Windows Vista: come eseguire un programma .exe nel cmd "As Administrator"

11

Sì è quello. Ho bisogno di eseguire un programma .exe nella riga dos cmd e deve funzionare come quando fai clic con il tasto destro e seleziona "Esegui come amministratore"

windows-vista shell command-line

— BinaryMisfit
fonte

Mi chiedevo anche questo. La mia soluzione era o di creare un file batch con il comando e lasciarlo sempre funzionare come admin, oppure aprire il cmd come admin. Ma sembra che ci dovrebbe essere una soluzione elegante.

— OregonGhost,

15

Windows ha un comando "runas" che agisce un po 'come sudo fa nei sistemi Unix-y. Prova a digitare "runas /?" nel prompt dei comandi.

— Neall
fonte

Oppure vederlo qui: technet.microsoft.com/en-us/library/cc771525.aspx

— Asaf R

Questa non è una risposta corretta, a meno che l'utente amministratore non sia abilitato con una password non vuota.

— jiggunjer,

7

Se esegui cmd stesso come amministratore, lo farà anche tutto il resto. Ho appena impostato un collegamento al prompt dei comandi che si apre come amministratore. Va bene tutto da lì.

— Kilhoffer
fonte

5

Ho usato un duo di script .cmd e .vbs chiamato elevate, funziona bene per le mie esigenze. Tutto ciò che serve è digitare

elevate [comando]

da Start> Esegui o dalla riga di comando e eseguirà il comando con i privilegi di amministratore. Spero che sia d'aiuto!

Ecco elevate.cmd:

:: //***************************************************************************
:: // ***** Script Header *****
:: //
:: // File:      Elevate.cmd
:: //
:: // Additional files required:  Elevate.vbs
:: //
:: // Purpose:   To provide a command line method of launching applications that
:: //            prompt for elevation (Run as Administrator) on Windows Vista.
:: //
:: // Usage:     elevate.cmd application <application arguments>
:: //
:: // Version:   1.0.0
:: // Date :     01/02/2007
:: //
:: // History:
:: // 1.0.0   01/02/2007  Created initial version.
:: //
:: // ***** End Header *****
:: //***************************************************************************


@echo off

:: Pass raw command line agruments and first argument to Elevate.vbs
:: through environment variables.
set ELEVATE_CMDLINE=%*
set ELEVATE_APP=%1

start wscript //nologo "%~dpn0.vbs" %*

e elevate.vbs:

' //***************************************************************************
' // ***** Script Header *****
' //
' // File:      Elevate.vbs
' //
' // Additional files required:  Elevate.cmd
' //
' // Purpose:   To provide a command line method of launching applications that
' //            prompt for elevation (Run as Administrator) on Windows Vista.
' //
' // Usage:     (Not used directly.  Launched from Elevate.cmd.)
' //
' // Version:   1.0.1
' // Date :     01/03/2007
' //
' // History:
' // 1.0.0   01/02/2007  Created initial version.
' // 1.0.1   01/03/2007  Added detailed usage output.
' //
' // ***** End Header *****
' //***************************************************************************


Set objShell = CreateObject("Shell.Application")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWshProcessEnv = objWshShell.Environment("PROCESS")

' Get raw command line agruments and first argument from Elevate.cmd passed
' in through environment variables.
strCommandLine = objWshProcessEnv("ELEVATE_CMDLINE")
strApplication = objWshProcessEnv("ELEVATE_APP")
strArguments = Right(strCommandLine, (Len(strCommandLine) - Len(strApplication)))

If (WScript.Arguments.Count >= 1) Then
    strFlag = WScript.Arguments(0)
    If (strFlag = "") OR (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
        OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "-?") OR (strFlag="h") _
        OR (strFlag = "?") Then
        DisplayUsage
        WScript.Quit
    Else
        objShell.ShellExecute strApplication, strArguments, "", "runas"
    End If
Else
    DisplayUsage
    WScript.Quit
End If


Sub DisplayUsage

    WScript.Echo "Elevate - Elevation Command Line Tool for Windows Vista" & vbCrLf & _
                 "" & vbCrLf & _
                 "Purpose:" & vbCrLf & _
                 "--------" & vbCrLf & _
                 "To launch applications that prompt for elevation (i.e. Run as Administrator)" & vbCrLf & _
                 "from the command line, a script, or the Run box." & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage:   " & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate application <arguments>" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate notepad ""C:\Windows\win.ini""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate cmd /k cd ""C:\Program Files""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command Set-Location 'C:\Windows'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage with scripts: When using the elevate command with scripts such as" & vbCrLf & _
                 "Windows Script Host or Windows PowerShell scripts, you should specify" & vbCrLf & _
                 "the script host executable (i.e., wscript, cscript, powershell) as the " & vbCrLf & _
                 "application." & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage with scripts:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate wscript ""C:\windows\system32\slmgr.vbs"" –dli" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command & 'C:\Temp\Test.ps1'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "The elevate command consists of the following files:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate.cmd" & vbCrLf & _
                 "    elevate.vbs" & vbCrLf

End Sub

— kolrie
fonte

Solo curioso, qual è il vantaggio di questo rispetto alle rune?

— tfinniga,

Duh! Mi hai! :) Non conoscerei il vantaggio sulle rune, ma quando non conosci le rune, questa è l'unica alternativa. Sono decisamente imbarazzato :)

Penso che sarebbe utile se una volta leggessimo quello che stiamo usando come script!

1

Questo duo è descritto su technet.microsoft.com/en-us/magazine/…

2

Il chiaro vantaggio dello script elevate è che ti consentono di elevare il tuo utente all'amministratore in UAC senza la necessità di fornire l'utente e la password dell'amministratore (a condizione che tu abbia effettuato l'accesso come utente amministratore). Runas.exe può farlo?

3

Devi usare il comando RunAs.exe.

Ecco alcune istruzioni: http://www.softtreetech.com/24x7/archive/53.htm

— Gthompson83
fonte

RunAs non è corretto. Non eleva il comando.

— surfasb,

2

Puoi anche premere il tasto Windows, digitare CMD, questo elencherà cmd nei programmi, fai clic destro -> Proprietà -> Compatibilità -> Esegui questo programma come amministratore

Questo funzionerà sempre come amministratore.

— Postino
fonte

Puoi anche usare Ctrl + Maiusc + Invio.

— Joey,

1

Poiché qualcuno ha pubblicato l'equivalente VBS, ecco una funzione Invoke-Admin per PowerShell

function Invoke-Admin() {
param ( [string]$program = $(throw "Please specify a program" ),
        [string]$argumentString = "",
        [switch]$waitForExit )

$psi = new-object "Diagnostics.ProcessStartInfo"
$psi.FileName = $program 
$psi.Arguments = $argumentString
$psi.Verb = "runas"
$proc = [Diagnostics.Process]::Start($psi)
if ( $waitForExit ) {
    $proc.WaitForExit();
}

}

— JaredPar
fonte

0

In breve:

Fare clic / premere Start, quindi CTRL + MAIUSC e INVIO. Confermare.

In dettaglio:

Premere il pulsante Start Digitare "cmd" (senza virgolette) immediatamente (1)
Tenere premuto CTRL e MAIUSC
Premere Invio
Confermare la finestra di dialogo Controllo dell'account utente di Windows Vista

(1) Significa immediatamente digitarlo nella casella Cerca, non nella casella Esegui.

— Mackaaij
fonte

0

È possibile utilizzare un VBScript come tale. Crea un .vbsfile, ad esempio ambika.vbs:

Set objShell = CreateObject(“Shell.Application”)
Set objWshShell = WScript.CreateObject(“WScript.Shell”)
Set objWshProcessEnv = objWshShell.Environment(“PROCESS”)

objShell.ShellExecute “C:\Windows\system32\cmd.exe”, “/k”, “”, “runas”

— Ambika Singh
fonte