Come trovare una cartella specifica in Outlook tra molte cartelle?

Ho Outlook 2013 e ho molte cartelle sul lato per tutti i miei contatti e le email dei fornitori ricevute da loro. Voglio essere in grado di trovare rapidamente una cartella senza dover scovarli tutti. qualcuno può aiutarmi qui, per favore

Outlook non fornisce la funzionalità diretta per cercare cartelle. Tuttavia ci sono soluzioni alternative che sono discusse in un'altra domanda qui su superutente: Come posso trovare una cartella persa in Outlook? . L'utente Loïc MICHEL ha creato alcuni script personalizzati per facilitare la ricerca di cartelle

Un sito web esterno (thetechieguy.com) ha anche creato una soluzione con istruzioni dettagliate Come cercare Outlook per il nome di una cartella

Spero che questo ti aiuti

A partire dal Trova o seleziona una cartella digitandone il nome :

1. Imposta lo stato attivo sulla cartella attiva nel riquadro di spostamento premendo CAMBIO + F6 (a seconda dell'attuale focus, potrebbe essere necessario premerlo più volte)
2. Dopo aver messo a fuoco il riquadro di spostamento, digitare le prime lettere del nome della cartella per selezionarlo.
3. La cartella corrente rimane la cartella attiva in modo da poter spostare facilmente i messaggi da essa all'altra cartella.

Nota: verranno trovate solo le cartelle attualmente visibili / espanse. Le sottocartelle compresse non saranno trovate. Guarda anche Avvio di Outlook con tutte le cartelle compresse / espanse .

Se non vuoi mantenere espanse le tue cartelle e vuoi effettivamente aprire una cartella specifica semplicemente digitandone il nome, allora questo Macro VBA da VBOffice farà il trucco.

Private m_Folder As Outlook.MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
  Dim Name$
  Dim Folders As Outlook.Folders

  Set m_Folder = Nothing
  m_Find = ""
  m_Wildcard = False

  Name = InputBox("Find name:", "Search folder")
  If Len(Trim$(Name)) = 0 Then Exit Sub
  m_Find = Name

  m_Find = LCase$(m_Find)
  m_Find = Replace(m_Find, "%", "*")
  m_Wildcard = (InStr(m_Find, "*"))

  Set Folders = Application.Session.Folders
  LoopFolders Folders

  If Not m_Folder Is Nothing Then
    If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
      Set Application.ActiveExplorer.CurrentFolder = m_Folder
    End If
  Else
    MsgBox "Not found", vbInformation
  End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
  Dim F As Outlook.MAPIFolder
  Dim Found As Boolean

  If SpeedUp = False Then DoEvents

  For Each F In Folders
    If m_Wildcard Then
      Found = (LCase$(F.Name) Like m_Find)
    Else
      Found = (LCase$(F.Name) = m_Find)
    End If

    If Found Then
      If StopAtFirstMatch = False Then
        If MsgBox("Found: " & vbCrLf & F.FolderPath & vbCRLF & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
          Found = False
        End If
      End If
    End If
    If Found Then
      Set m_Folder = F
      Exit For
    Else
      LoopFolders F.Folders
      If Not m_Folder Is Nothing Then Exit For
    End If
  Next
End Sub

Cartelle rapide il componente aggiuntivo fa esattamente questo. Si tratta di un prodotto commerciale sviluppato dalla mia azienda, ma è possibile utilizzare la prova gratuita per trovare la / le cartella / e come richiesto.