In PotPlayer c'è un modo per spostare O copiare il file in riproduzione corrente in un'altra directory (oltre al cestino)? O in qualche modo con AutoHotKey o simili?

Quando si esaminano più file video per l'editing video e la libreria mgmt, PotPlayer seleziona molte caselle per una rapida revisione, ma non riesce a trovarlo.

Pensavo che avrei contattato qui per qualsiasi cosa mi sarei perso O suggerimenti usando autohotkey o qualsiasi altra possibile soluzione.

Tenere tutto in PotPlayer mi farebbe risparmiare un sacco di tempo.

Non so nulla di PotPlayer, potrebbe esserci un modo migliore per farlo completamente in background. Abbastanza facile da fare in AutoHotkey anche se non ti dispiace alcune finestre di dialogo che spuntano e scompaiono di nuovo.

Questo script apre la finestra di dialogo FileInfo, copia il nome file negli Appunti e quindi esegue una filecopy di quel percorso su un altro percorso. Modifiche che dovrai apportare allo script seguente:

• Rimuovi MsgBoxuna volta che hai verificato che funziona per afferrare il nome file corrente
• La destinazione della copia è c:\tempattualmente hardcoded per → cambiarla come preferisci
• È possibile modificare il tasto di scelta rapida assegnato nello script seguente se si desidera (attualmente F8)
• Impostare l'opzione per sovrascrivere nell'istruzione filecopy se lo si desidera (o no)

Questo script è stato testato fino alla finestra di messaggio che mostra il nome file corrente che prende, quindi supponendo che la filecopy funzionerà bene dopo di ciò - se non è un punto di partenza con cui giocare.

Esempio di script:

#Persistent
SetTitleMatchMode, 2
Return

#IfWinActive, ahk_class PotPlayer
F8::
    SendInput ^{F1}         ; Pull up info dialog
    WinWaitActive, Playback/System Information,,2
    If ErrorLevel {
        Tooltip, Couldn't find dialog... exiting...
        Sleep 2000
        ToolTip
        Return          ; couldn't find dialog
    }

    lastClipboard := ClipboardAll       ; Save existing clipboard contents

    SendInput ^{Tab 2}      ; Focus tab control at top
    Sleep 100
    SendInput {Right}       ; Focus FileInfo tab
    Sleep 100
    SendInput {Space}       ; Select FileInfo
    Sleep 100

    SendInput !c            ; Select copy to clipboard
    Sleep 100
    SendInput {Space}       ; Execute
    Sleep 100

    SendInput !c            ; Select close
    Sleep 100
    SendInput {Space}       ; execute
    Sleep 100

    FileName := ""
    Loop, Parse, % FileInfo:=Clipboard, `n
    {
        If InStr(A_LoopField, "Complete name") {
            FileName := Trim(Substr(A_LoopField, InStr(A_LoopField, ":")+1)) ; get path and file after colon and trim spaces
            Break
        }
    }

    Clipboard := lastClipboard ; restore previous clipboard

    If (FileName = "") {
        Tooltip, Couldn't find filename... exiting...
        Sleep 2000
        ToolTip
        Return
    }

    ; Remove this when no longer needed...
    MsgBox % "Filename Found: " FileName

    ; Put the target directory of choice here instead of c:\temp
    ; add a 1 as the third arg to overwrite if needed
    FileCopy, % FileName, % "C:\temp"     

Return