Copia e incolla un file 200 volte con nuovi nomi

Ho una cartella con un file chiamato 'template.xlsx':, e centinaia di file denominati:

• old_2301 Item 1.xlsx
• old_2014 Item 2.xlsx
• old_5321 Item 3.xlsx
• ...
• old_3212 Item 200.xlsx

Voglio copiare il file template.xksxe creare 200 nuovi file:

• 2301 Item 1.xlsx
• 2014 Item 2.xlsx
• 5321 Item 3.xlsx
• 3212 Item 200.xlsx

Ho provato qualcosa del tipo:

Nella cartella, digita Shift+ Maiusc: seleziona "apri qui la finestra di comando"

for %a in (*.*) do copy "template.xlsx" ... ren ...?

Voglio rinominare i template.xlsxfile copiati con lo stesso nome degli altri file, ma con i old_ritagli.

C'è un modo semplice per fare questo?

Voglio copiare template.xlsxil nome degli altri file, con old_rimosso

Utilizzare il seguente file batch:

@echo off
setlocal enabledelayedexpansion
rem get list of file names
for /f "usebackq tokens=*" %%i in (`dir /b old_*.xlsx`) do (
  rem save the filename
  set _name=%%i
  rem remove old_ from the name
  set _name=!_name:old_=!
  rem do the copy to the modified name
  copy "template.xlsx" "!_name!"
  )
endlocal

Ulteriori letture

• Un indice AZ della riga comandi CMD di Windows
• Un elenco classificato di comandi CMD di Windows
• dir - Visualizza un elenco di file e sottocartelle.
• enabledelayedexpansion - L'espansione ritardata comporterà l'espansione delle variabili al momento dell'esecuzione piuttosto che al momento dell'analisi.
• for / f - Comando loop contro i risultati di un altro comando.
• modifica / sostituisci variabile: consente di modificare e sostituire i caratteri assegnati a una variabile stringa.

Devi usare i file nominati old_*come origine del nome e dividerli nel carattere di sottolineatura.

@Echo off
For /f "tokens=1* delims=_" %%A in (
    'Dir /B /A-D "old_* Item *.xlsx"'
) Do Echo Copy template.xlsx "%%B"

Se l'output sembra OK, rimuovere l'eco davanti alla copia.

Spiegazione dell'analisi per le opzioni / f:

nome file old_2301 Articolo 1.xlsx
delims _
token 1 _ * (resto)
per var %% A %% B

Una variante per la riga di comando senza batch:

For /f "tokens=1* delims=_" %A in ('Dir /B /A-D "old_*.xlsx"') Do Copy template.xlsx "%B"

A meno che non volessi davvero un programma che potessi eseguire più e più volte, se questo fosse solo una tantum o un po 'fuori uso, avrei usato Notepad ++ o qualsiasi altro editor di testo con blocco copia e incolla. Aprire un prompt dei comandi nella relativa directory e digitare dir/b > 1.txt, che si traduce ad esempio in:

D:\MiscJunk\1>type 1.txt
1.txt
old_2014 Item 2.txt
old_2301 Item 1.txt
old_5321 Item 3.txt
template.txt

Modifica 1.txt in Notepad ++ e aggiungi tutte queste righe necessarie:

copy template.txt ""
copy template.txt ""
copy template.txt ""

Blocca copia (tasti freccia Alt Shift) il testo:

2014 Item 2.txt
2301 Item 1.txt
5321 Item 3.txt

e incollalo tra le virgolette:

copy template.txt "2014 Item 2.txt"
copy template.txt "2301 Item 1.txt"
copy template.txt "5321 Item 3.txt"

Quindi, dopo aver verificato che i comandi siano corretti e regolati di conseguenza, basta copiare e incollare quei comandi nel prompt dei comandi, ottenendo:

D:\MiscJunk\1>dir/b
2014 Item 2.txt
2301 Item 1.txt
5321 Item 3.txt
...

Questo metodo è ultra-semplice senza bisogno di debug e c'è molto poco che può andare storto. Annullare blocchi di comandi in Notepad ++ è qualcosa che faccio abbastanza regolarmente.