Excel auto nuovo foglio con copia di colonna e data di oggi

Voglio scrivere una routine VBA che sarebbe "giornaliera"

• crea un nuovo foglio
• dai a quel nuovo foglio un nome del modulo GG.MM.AA (con zeri iniziali), in base alla data odierna (ad esempio, 25.07.18 )
• copiare i valori dalle colonne A e B del mio DataInput foglio nel nuovo foglio.

Cosa intendo per "quotidiano"? Solo se l'ora corrente è = o & gt; un determinato orario, quindi creare il foglio, altrimenti ignorarlo.

Non penso sia difficile da gestire. Ho provato a combinare alcune formule per metterle insieme ma mi danno un errore tutto il tempo.

Stavo pensando a qualcosa

Option Explicit
Sub ReportSheet_Today()
    Dim szTodayDate As String

    szTodayDate = Format(Date, "dd.mm.yy")
    On Error GoTo MakeSheet
    Sheets(szTodayDate).Activate
    If Time < TimeValue("9:00:00") Then
        'MakeSheet:
        Sheets.Add , Worksheets(Worksheets.Count)
        ActiveSheet.Name = szTodayDate
        Sheets("DataInput").Select
        Range("A:A").Copy
        Sheets("szTodayDate").Select
        Range("A:A").Select
        ActiveSheet.Paste
    End IF
End Sub

L'errore è qui:

Sheets("szTodayDate").Select

szTodayDate non è il nome del foglio; è una variabile locale che contiene una stringa che rappresenta il nome del foglio ... ma la stai usando come stringa letterale , quindi VBA sta cercando di dereferenziare un oggetto di lamiera che è letteralmente chiamato "szTodayDate" ... e dal momento che non riesce a trovarlo, boom, errore di run-time 9.

Rimuovi le doppie virgolette:

Sheets(szTodayDate).Select

Ora stai per dereferenziare un oggetto foglio chiamato dopo il valore di il szTodayDate variabile stringa, che è probabilmente quello che intendevi.

Prossimi passi...

Trascina la logica di creazione dei fogli in una propria procedura separata; scrivendo piccole procedure specializzate che fai una cosa e fallo bene , renderà la tua vita molto più facile in linea.

Puoi sfruttare i valori di ritorno delle funzioni: Worksheets.Add restituisce un riferimento all'oggetto del foglio di lavoro che è stato creato: catturando tale riferimento in una variabile oggetto locale, ne rimuovi la necessità Select e poi a lavorare fuori ActiveSheet.

Puoi anche fornire un destinazione parametro a Range.Copy, rendendo l'intero select-copia-select-incolla operazione un one-liner.

Public Function CreateReportSheet(ByVal reportDate As Date) As Worksheet

    Dim reportSheet As Worksheet
    Set reportSheet = AddNamedWorksheet(ThisWorkbook, Format$(reportDate, "dd.mm.yy"))

    'only needed if the sheet doesn't exist at compile-time.
    'if it *does* exist at compile-time, just set the sheet's (Name) property to "inputSheet".
    'that identifier will then be globally available anywhere in the project.
    'Dim inputSheet As Worksheet
    'Set inputSheet = ThisWorkbook.Worksheets("DataInput")

    inputSheet.Range("A:A").Copy reportSheet.Range("A:A")
    Set CreateReportSheet = reportSheet

End Function

Public Function AddNamedWorksheet(ByVal wb As Workbook, ByVal sheetName As String) As Worksheet
    Dim sheet As Worksheet
    Set sheet = wb.Worksheets.Add
    On Error Resume Next ' naming the sheet will throw if name already exists
        sheet.Name = sheetName
    On Error GoTo 0 ' restore error handling
    Set AddNamedWorksheet = sheet
End Function