Come posso cercare e sostituire in più file di Word?

Sto cercando un modo per cercare e sostituire molti file Word (.doc) (ai fini dell'automazione del processo).

Il software che ho trovato finora mi permette solo di cercare, ma non di sostituirlo.

Come posso farlo con Word?

Puoi provare VBA Trova e sostituisci (link memorizzato nella cache).

Trova e sostituisci © VBA fornisce un metodo per trovare e sostituire il testo in qualsiasi punto di un documento (o raccolta di documenti) utilizzando coppie di variabili "trova" e "sostituisci" definite dall'utente o un elenco definito dall'utente di "trova" e "sostituisci" accoppiamenti. Fornisce inoltre un metodo per trovare il testo e sostituire il testo trovato con una voce "Glossario" o "Building Block" definita dall'utente.

Allo scopo di eseguire più sostituzioni normali e basate su caratteri jolly in più file MS Word situati in più cartelle in una determinata cartella principale, ho creato la seguente macro VBA. Per usarlo, devi cambiare il contenuto delle seguenti variabili (costanti):

• rootPath : cartella radice in cui si trovano le cartelle contenenti documenti Word.
• findTextsWild e replaceTextsWild : matrice di espressioni trova e sostituisci basate su caratteri jolly.
• findTexts e replaceTexts : array di normali espressioni find e sostituisci.

Forse lo troverai utile :-)

Sub GlobalTextReplacement()
' Root under which all manuals are stored
Dim rootPath As String
rootPath = "c:\Data\Manuals\"

' Find and replace text for wildcard replacement. Performed first.
Dim findTextsWild() As Variant, replaceTextsWild() As Variant
findTextsWild = Array("[ ]{2;}", "[cC]onfiguration[/ ]@[pP]olicy [rR]epository", "[sS]ervlet[- ]@[fF]ilter")
replaceTextsWild = Array(" ", "Configuration/Policy Repository", "Servlet-Filter")

' Find and replace text for normal case insensitive replacement. Performed second.
Dim findTexts() As Variant, replaceTexts() As Variant
findTexts = Array("DirX Access", "Policy Repository", "User Repository", "Servlet", "servletfilter", "SAML assertion", "DirX Access Server", "DirX Access Manager", "Deployment Manager", "Policy Manager", "Client SDK", "^p ", " ^p")
replaceTexts = Array("DirX Access", "Policy Repository", "User Repository", "Servlet", "Servlet-Filter", "SAML assertion", "DirX Access Server", "DirX Access Manager", "Deployment Manager", "Policy Manager", "Client SDK", "^p", "^p")

' Main code
Application.ScreenUpdating = False

Dim dirNames(20) As String
Dim dirNamesCount As Integer
dirNamesCount = 0

Dim dirName As String
dirName = Dir$(rootPath & "*", vbDirectory)
Do Until LenB(dirName) = 0
    Dim dirPath As String
    dirPath = rootPath & dirName
    If ((GetAttr(dirPath) And vbDirectory) = vbDirectory) And (dirName <> ".") And (dirName <> "..") Then
        dirNamesCount = dirNamesCount + 1
        dirNames(dirNamesCount) = dirPath & "\"
    End If
    dirName = Dir$
Loop

Do While dirNamesCount > 0
    Dim fileName As String
    dirName = dirNames(dirNamesCount)
    dirNamesCount = dirNamesCount - 1
    fileName = Dir$(dirName & "*.doc", vbDirectory)
    Do Until LenB(fileName) = 0
        Dim filePath As String
        filePath = dirName & fileName
        fileName = Dir$

        Dim document As document
        Set document = Documents.Open(filePath)
        document.TrackRevisions = True

        document.Select

        Dim i As Integer, maxIndex As Integer
        maxIndex = UBound(findTextsWild)
        For i = LBound(findTextsWild) To maxIndex
            With Selection.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Text = findTextsWild(i)
                .Replacement.Text = replaceTextsWild(i)
                .Execute Replace:=wdReplaceAll, Forward:=True, _
                    Wrap:=wdFindContinue, MatchWildcards:=True
            End With
        Next

        maxIndex = UBound(findTexts)
        For i = LBound(findTexts) To maxIndex
            With Selection.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Text = findTexts(i)
                .Replacement.Text = replaceTexts(i)
                .Execute Replace:=wdReplaceAll, Forward:=True, _
                    Wrap:=wdFindContinue, MatchCase:=False, MatchWildcards:=False
            End With
        Next

        document.Save
        document.Close
    Loop
Loop

Application.ScreenUpdating = True
End Sub

Non può essere fatto in Microsoft Word stesso?

Si trova nel menu Modifica (Word 2003) o nella scheda Home / sezione Modifica (Word 2007)

http://office.microsoft.com/en-us/word/HA012303921033.aspx

Se non possiedi Microsoft Word e stai cercando un'alternativa gratuita che ti aiuterà, prova OpenOffice.org .

Non penso che questo ti aiuterà se stai cercando un modo per automatizzare questo processo.

Notepad ++ È in grado di farlo utilizzando "Trova nei file"

Option Explicit

Public Sub BatchReplaceAll()
    Dim FirstLoop As Boolean
    Dim myFile As String
    Dim PathToUse As String
    Dim myDoc As Document
    Dim Response As Long

    PathToUse = ActiveDocument.Path
    On Error Resume Next
    Documents.Close SaveChanges:=wdPromptToSaveChanges
    FirstLoop = True
    myFile = Dir$(PathToUse & "\*.doc*")

    While myFile <> ""
        Set myDoc = Documents.Open(PathToUse & "\" & myFile)
        If FirstLoop Then
            Application.Dialogs(wdDialogEditReplace).Show
            FirstLoop = False

            Response = MsgBox("Do you want to process the rest of the files in this folder", vbYesNo)
            If Response = vbNo Then Exit Sub
        Else
            With Dialogs(wdDialogEditReplace)
                .ReplaceAll = 1
                .Execute
            End With
        End If
        myDoc.Close SaveChanges:=wdSaveChanges
        myFile = Dir$()
    Wend
End Sub