Ottieni il nome della cartella corrente con un comando DOS?

È possibile ottenere il nome della cartella corrente (non il percorso della directory corrente) utilizzando un comando DOS? Se é cosi, come?

Il più vicino che ho avuto è stato questo ma non lo fa:

for /f "delims=\" %%a in ("%CD%") do set CURR=%%a
echo.DIR: %CURR%

nota: il tentativo sopra è stato quello di tentare di tokenizzare la stringa e ottenere l'ultimo token impostato come variabile CURR.

Il modo più breve che ho trovato:

for %I in (.) do echo %~nxI

o all'interno di uno script .bat:

for %%I in (.) do echo %%~nxI

o in .bat con Ottieni valore in variabile.

for %%I in (.) do set CurrDirName=%%~nxI
echo %CurrDirName%

Spiegazione: http://www.robvanderwoude.com/ntfor.php

nx significa solo nome file ed estensione

Se vuoi conoscere la posizione corrente del file batch (e se la tua Windows non è una versione molto antica), digita for /?una finestra 'DOS box'. Scorri verso il basso. Leggere.

Scoprirai che ora puoi leggere ( dall'interno del file batch) queste variabili:

%0      - as the name how this batchfile was called
%~d0    - as the drive letter where this batchfile is located ('\\' in case of share)
%~p0    - as path (without the drive letter) where this batchfile is located
%~n0    - as filename (without suffix) of this batchfile
%~x0    - as filename's suffix (without filename) of this batchfile
%~a0    - as this batchfile's file attributes
%~t0    - as this batchfile's date+time
%~z0    - as this batchfile's filesize
%~dpnx0 - as this batchfile's fully qualified path+filename
[... and then some more ...]

Questo funziona per molti casi. Supponiamo che venga chiamato il file batch mytest.bat. Puoi chiamarlo in diversi modi:

1. ..\..\to\mytest.bat ............................... (percorso relativo)
2. d:\path\to\mytest.bat........................... (percorso completo)
3. \\fileserver\sharename\mytest.bat... (percorso sulla condivisione remota)

... e otterrai sempre il giusto valore nelle tue variabili.

Personalmente mi è piaciuta la risposta di Toms, fino a quando ha lottato con i punti nei nomi delle directory. Questo mi ha dato un suggerimento:

for /f "delims=\" %%a in ("%cd%") do echo topmost dir: %%~nxa

La risposta di Tom è buona, ma se hai un nome di directory con un punto (cioè wxwidgets-2.9.4) otterrai solo il nome completo. Quindi questo produrrebbe invece wxwidgets-2.9 ​​perché .4 è stato trattato come un'estensione (Sì, anche se è un nome di directory!).

Per ottenere il nome di output completo devi aggiungere l'estensione alla fine:

FOR %I IN (.) DO Echo %~nI%~xI

e in modalità file batch:

FOR %%I IN (.) DO Echo %%~nI%%~xI

O ovviamente, imposta invece una variabile nel file batch:

FOR %%I IN (.) DO SET CurrentD=%%~nI%%~xI

Un altro modo è:

set "MyPath=%~dpnx0" & call set "MyPath=%%MyPath:\%~nx0=%%" 
echo MyPath=%MyPath%  

funziona con "." e spazi nel percorso

Che cosa fa?

1. metti l'intero nome del file (driveletter-path-nomefile-estensione) in MyPathVar

2. rimuove il nome del file e l'estensione da MyPathvar

Funziona anche con percorsi UNC. Se hai bisogno di una barra rovesciata alla fine del percorso. Rimuovere il comando \after MyPathnel secondo set set, ad es.

set "MyPath=%%MyPath:%~nx0=%%"

È possibile ottenere la directory corrente in una variabile. One-liner:

set a=%cd%

Controllare con

echo %a%

semplice

for %%d in ("%CD%") do echo %%~nxd

o

set "sPath=."
for %%d in ("%sPath%") do set "sDirName=%%~nxd"

Fai attenzione alla barra rovesciata della fine del percorso, non deve essere barra rovesciata della fine.

La mia risposta in questa discussione lo fa in 3 semplici righe:

@echo off
SET "CDIR=%~dp0"
:: for loop requires removing trailing backslash from %~dp0 output
SET "CDIR=%CDIR:~0,-1%"
FOR %%i IN ("%CDIR%") DO SET "PARENTFOLDERNAME=%%~nxi"
ECHO Parent folder: %PARENTFOLDERNAME%
ECHO Full path: %~dp0
pause>nul

Questo funziona per me da un file batch. Restituisce il nome della directory di lavoro corrente.

pushd %1 & for %%i in (.) do @echo %%~ni