Vim: Come sincronizzare NERDTree con il percorso del file della scheda attualmente aperto?

Quando apro una nuova scheda con un percorso diverso dal file precedente in VIM, NERDTree rimarrà comunque la stessa gerarchia di directory del file precedente.

Esiste un collegamento di sincronizzazione per cambiare la directory principale corrente nella directory del nuovo file aperto?

Non sono sicuro se esiste un modo specifico per NERDTree per farlo, ma puoi sempre configurare Vim in modo che imposti la directory di lavoro sulla directory del file corrente :

autocmd BufEnter * lcd %:p:h

Ora tutto ciò che devi fare dopo aver aperto un file in una nuova scheda è :NERDTreeTogglenella nuova scheda stessa.

Uso il seguente mapping per visualizzare il buffer corrente in NERDTree:

 map <leader>r :NERDTreeFind<cr>

lancia un segno% alla fine come un boss

:NERDTree %

ho questo nel mio .vimrc, mappa Ctrl+ oper attivare / disattivare nerdtree nella directory del buffer corrente:

map <C-o> :NERDTreeToggle %<CR>

Ho trovato educative entrambe le risposte esistenti e le ho combinate con successo in modo che il comportamento sia più simile a quello che molte persone si aspetterebbero da un IDE: fare clic su una finestra / buffer aperto e fare in modo che il file sia evidenziato in NERDTree. Ho inserito questo nel mio ~ / .vimrc:

autocmd BufEnter * if &modifiable | NERDTreeFind | wincmd p | endif

Cosa fa questo:

1. autocmd BufEnter - viene eseguito ogni volta che ti concentri su un buffer (inclusa la finestra NERDTree)
2. if &modifiable - quando fai clic sulla finestra NERDTree, non fare nient'altro (la finestra NERDTree non è modificabile)
3. wincmd p- NERDTreeFind lascia il cursore focalizzato su NERDTree; questo ritorna alla finestra su cui inizialmente ti eri concentrato

Nota che questo non funzionerà su nessun altro buffer che non sia modificabile, ma generalmente è una buona cosa; altrimenti (ad esempio) ogni volta che :helpentri in vim, NERDTree trova e focalizza la directory in cui sono archiviati i file di aiuto - probabilmente non è qualcosa che vuoi che faccia.

Quella soluzione a una riga ha funzionato alla grande all'inizio per me, ma ho presto scoperto che provoca l'attivazione di NERDTree ogni volta che apro un file e, di conseguenza, impedisce che NERDTree venga mai chiuso! Se non vuoi usare NERDTree a tempo pieno, inseriscilo nel tuo .vimrc:

" returns true iff is NERDTree open/active
function! rc:isNTOpen()        
  return exists("t:NERDTreeBufName") && (bufwinnr(t:NERDTreeBufName) != -1)
endfunction

" calls NERDTreeFind iff NERDTree is active, current window contains a modifiable file, and we're not in vimdiff
function! rc:syncTree()
  if &modifiable && rc:isNTOpen() && strlen(expand('%')) > 0 && !&diff
    NERDTreeFind
    wincmd p
  endif
endfunction

autocmd BufEnter * call rc:syncTree()

Mi sono imbattuto in questa domanda ieri, dopo alcune ore di scavo, ho inviato una richiesta pull al repository nerdtree di scrooloose introducendo un NERDTreeCWDcomando che cambia la radice dell'albero NERD nella directory di lavoro corrente (Aggiornamento del 2012-11-12: il PR è stato unito in il master upstream, dovrebbe essere utilizzabile su una versione aggiornata). Con questa modifica, questa domanda può essere semplicemente risolta dal seguente codice.

autocmd BufEnter * silent! if bufname('%') !~# 'NERD_tree_' | cd %:p:h | NERDTreeCWD | wincmd p | endif

Confronta con l'approccio di @ shinzui e @ Lambart NERDTreeFind, questo fa esattamente quello che ha posto la domanda. L'utilizzo NERDTreeFindcambierà la posizione di scorrimento del nerdtree e il risultato non sarà sempre lo stesso (se CWD è nella radice dell'albero NERD, espande semplicemente il nodo invece di cambiarlo).

Confronta con la risposta di @Yaser Sulaiman, questa soluzione ha sempre una finestra ad albero NERD aperta e può essere facilmente codificabile. Se una finestra ad albero NERD è già stata aperta, NERDTreeTogglesarà necessario attivare due volte l'uso (prima chiudi quella esistente, quindi riaprila), sfortunatamente, la seconda apertura salterà l'intera elaborazione cwd.

Questo si comporta come :NERDTreeTogglema mostrerà il file attualmente aperto in NERDTree. Se non hai ancora aperto un file (ovvero, hai appena inserito la vimtua riga di comando) mostra NERDTree /home.

Metti questo nel tuo .vimrc:

" Open NERDTree in the directory of the current file (or /home if no file is open)
nmap <silent> <C-i> :call NERDTreeToggleInCurDir()<cr>
function! NERDTreeToggleInCurDir()
  " If NERDTree is open in the current buffer
  if (exists("t:NERDTreeBufName") && bufwinnr(t:NERDTreeBufName) != -1)
    exe ":NERDTreeClose"
  else
    exe ":NERDTreeFind"
  endif
endfunction

Applico entrambe le soluzioni da Cambia directory corrente utilizzando NERDTree : utilizzare cdper impostare la directory di lavoro NERDTree sulla directory corrente e Cper impostare il nodo radice NERDTree sulla directory corrente

Penso che questo plugin sia quello che vuoi https://github.com/jistr/vim-nerdtree-tabs

Ho trovato la risposta che Matthias ha pubblicato per essere un'ottima risposta con un problema, non funziona bene in un paio di casi limite. Funziona un po 'meglio con la modifica seguente:

function! NERDTreeToggleInCurDir()
  " If NERDTree is open in the current buffer
  if (exists("t:NERDTreeBufName") && bufwinnr(t:NERDTreeBufName) != -1)
    exe ":NERDTreeClose"
  elseif bufname('%')
    exe ":NERDTreeFind"
  else
    exe ":NERDTreeCWD"
  endif
endfunction