Crea un collegamento simbolico nel Finder di Mac OS X.

C'è un modo per ottenere la stessa funzionalità del comando unix ln -snel Finder di Mac OS X (OS 10.5)? Voglio essere in grado di creare collegamenti simbolici mentre lavoro nelle finestre del Finder senza aprire il Terminale.

Si noti che il Make Aliascomando nel Finder non è quello che voglio perché quegli alias non possono essere navigati nel Terminale (ma i collegamenti creati con ln -spossono essere navigati sia dal Terminale che dal Finder).

Che dire della creazione di collegamenti simbolici nel Finder tramite AppleScript ?

Ecco lo script più rilevante in quel link:

on run
    open {choose file with prompt "Choose a file to create a symbolic link:" without invisibles}
end run

on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Basta incollarlo in AppleScript Editor e salvarlo come un'applicazione . Quindi puoi trascinarlo sulla barra degli strumenti del Finder o collegarlo sul dock .

SymbolicLinker farà esattamente quello che stai cercando ed è gratuito.

Uno script di Apple al link fornito dall'utente nuc ha risposto alla mia domanda. Ecco lo script di mele riprodotto nel caso in cui il link scompaia.

Ho preferito la sceneggiatura fornita dal commentatore jonn8n, che è stata anche riprodotta come articolo di Macworld .

on run
    open {choose file with prompt ¬
        "Choose a file to create a symbolic link:" without invisibles}
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path ¬
                & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

L'ho salvato come un'applicazione usando Script Editor e ho trascinato l'applicazione nella barra laterale del Finder in modo da poter ora creare collegamenti simbolici trascinando i file o le cartelle sull'icona dell'applicazione.

Path Finder aggiunge questo al tuo Finder e aggiunge molte altre funzionalità.

Utilizzare Automator.app per creare un servizio che esegue uno script bash. È più semplice di AppleScript e più affidabile dell'installazione di software di terze parti.

for f in "$@"
do
    ln -s "$f" "$f.symlink"
done

Quindi è possibile accedere al comando Crea collegamento simbolico dal menu Servizi :

Il risultato:

Un possibile miglioramento su questo script potrebbe essere la modifica del gestore di esecuzione per utilizzare i file attualmente selezionati dal Finder, in questo modo:

on run
    tell application "Finder" to set sel to selection
    open sel
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files as alias)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            try
                do shell script "ln -s " & quoted form of posix_path ¬
                    & " " & quoted form of (posix_path & ".sym")
            on error
                try
                    do shell script "ln -s " & quoted form of posix_path ¬
                        & " " & quoted form of (posix_path & ".sym") with administrator privileges

                end try
            end try
        end try
    end repeat
end open

È inoltre possibile modificare [application] /Contents/Info.plist per aggiungere

<key>LSUIElement</key>
<true/>

Poco prima dell'ultimo </dict>. Ciò significherebbe che l'app verrà eseguita in background e non verrebbe in primo piano quando si fa clic su di essa.

Inoltre, in Snow Leopard dove SymbolicLinker non funziona, è possibile creare un servizio con Automator per eseguire il comando Terminale o AppleScript per creare un collegamento simbolico.

Un altro AS:

tell application "Finder"
    repeat with f in (get selection)
        set p to POSIX path of (f as text)
        set p2 to POSIX path of (desktop as text) & name of f
        do shell script "ln -s " & quoted form of p & " " & quoted form of p2
    end repeat
end tell

Prova a cercare qui: http://www.techiecorner.com/528/how-to-create-shortcut-in-mac-os-x/

Questo è già integrato in OSX se si preme il tasto di controllo quando si fa clic su qualcosa.