Sto cercando uno strumento per consentire la ricerca incrementale inversa con il supporto di espressioni regolari semplici (o solo più corrispondenze). Ad esempio, se voglio trovare il comando 'foo bar baz', potrei fare qualcosa di simile al seguente per trovare rapidamente il comando:

CRTL-R (avvia la ricerca) digita "pippo" (corrisponde al comando più recente usando pippo) continua a digitare "pippo | baz" (corrisponde al comando più recente contenente "pippo" E "baz".

Esiste qualcosa del genere? In caso negativo, come potrei implementarlo da solo?

Widget personalizzato history-incremental-multi-searchperzsh

Impostare

Crea una directory e includila nella tua $fpathAd esempio, ho creato una directory ~/.zsh/functionse la riga fpath=($HOME/.zsh/functions $fpath)nella mia .zshrc.

Inserire quanto segue in un file denominato history-incremental-multi-searchin quella directory.

emulate -L zsh
setopt extended_glob

local oldbuffer=$BUFFER
local -i oldcursor=$CURSOR

local dir                # search direction
local chars              # input buffer
local -a words           # search terms
local -a found           # all history items that match first term
local -i hindex=$HISTNO  # current 
local -i lmatch          # last matched history item (for prev/next)

if [[ $WIDGET == *forward* ]]; then
    dir=fwd
else
    dir=bck
fi

function find-next {
    # split the input buffer on spaces to get search terms
    words=(${(s: :)chars})

    # if we have at least one search term
    if (( $#words )); then
        # get all keys of history items that match the first
        found=(${(k)history[(R)*$words[1]*]})
        if (( $#found )); then
            # search in widget direction by default
            # but accept exception in $1 for "prev match"
            search-${1:-$dir}
        else
            # no matches
            lmatch=$HISTNO
        fi
    else
        # no search terms
        lmatch=$HISTNO
        BUFFER=$oldbuffer
        CURSOR=$oldcursor
    fi
}

function search-fwd {
    # search forward through matches
    local -i i
    for (( i = $#found; i > 0; i-- )); do
        # but not before hindex as we're searching forward
        if [[ $found[$i] -gt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function search-bck {
    # search backward through matches
    local -i i
    for (( i = 1; i <= $#found; i++ )); do
        # but not beyond hindex as we're searching backward
        if [[ $found[$i] -lt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function set-match {
    # match history item against all terms and select it if successful
    local match=1
    local -i i
    for (( i = 2; i <= $#words; i++ )); do
        if [[ $history[$1] != *$words[$i]* ]]; then
            match=0
            break
        fi
    done
    if [[ $match -ne 0 ]]; then
        lmatch=$1
        BUFFER=$history[$1]
        CURSOR=$#BUFFER
        break
    fi
}

# display sub prompt
zle -R "${dir}-i-search-multi:"

# handle input keys
while read -k; do
    case $REPLY in
        # next
        $'\C-n' )
            hindex=$lmatch
            find-next
            ;;
        # prev
        $'\C-p' )
            hindex=$lmatch
            if [[ $dir == fwd ]]; then
                find-next bck
            else
                find-next fwd
            fi
            ;;
        # break
        $'\e' | $'\C-g' )
            BUFFER=$oldbuffer
            CURSOR=$oldcursor
            break
            ;;
        # accept
        $'\C-m' | $'\C-j' )
            if [[ $lmatch -eq $HISTNO ]]; then
                BUFFER=$oldbuffer
                CURSOR=$oldcursor
            else
                HISTNO=$lmatch
            fi
            break
            ;;
        # erase char
        $'\C-h' | $'\C-?' )
            chars=$chars[1,-2]
            hindex=$HISTNO
            find-next
            ;;
        # erase word
        $'\C-w' )
            if [[ $chars =~ \  ]]; then
                chars=${chars% *}
            else
                chars=
            fi
            hindex=$HISTNO
            find-next
            ;;
        # kill line
        $'\C-u' )
            chars=
            hindex=$HISTNO
            find-next
            ;;
        # add unhandled chars to buffer
        * )
            chars=${chars}${REPLY}
            hindex=$HISTNO
            find-next
            ;;
    esac

    zle -R "${dir}-i-search-multi: $words"
done

Inseriscilo o cercalo dal tuo .zshrc:

autoload -U history-incremental-multi-search

# make new widgets from function
zle -N history-incremental-multi-search-backward history-incremental-multi-search
zle -N history-incremental-multi-search-forward history-incremental-multi-search

# bind the widgets to keys
bindkey '^Xr' history-incremental-multi-search-backward
bindkey '^Xs' history-incremental-multi-search-forward

Uso

Si dovrebbe ora essere in grado di avviare una ricerca incrementale all'indietro con Ctrl+X, r, avanti con Ctrl+X, s.

Digita i termini di ricerca separati da spazio. Sono disponibili i seguenti tasti per controllarlo:

• ← Backspace: cancella carattere

• Ctrl+W: cancella la parola

• Ctrl+U: linea di uccisione

• Ctrl+N: la prossima partita

• Ctrl+P: partita precedente

• Ctrl+G/ Esc: annulla la ricerca

• Enter: accetta

Questa soluzione può probabilmente essere semplificata abbastanza. È più una prova funzionale del concetto, con molto spazio per miglioramenti.

Puoi consultare la tua cronologia:

history | egrep '(foo|baz)'

Spero che aiuti.