È possibile impostare Internet Explorer come browser predefinito per l'avvio dalla riga di comando?

Ho un'applicazione Web che funziona solo con Internet Explorer, ma se succede che Firefox è il browser predefinito, non funziona. Gli utenti si trovano in un ambiente di dominio e anche se provo ad avviare la nostra applicazione da un batch in questo modo:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

l'applicazione non si avvia se non cambio manualmente il browser.

Questo comando imposterà IE come browser predefinito:

shmgrate.exe OcinstallreinstallIE

Questa politica dovrebbe impedire alle persone di determinare il browser predefinito.

puoi provare questo, funzionerà

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

l'errore nel comando era che si startaspetta che la prima stringa tra virgolette sia il titolo dell'applicazione, che in questo caso è possibile lasciare vuota.

per l'impostazione iexplorer.execome browser Web predefinito del sistema, è possibile utilizzare assoce ftypecomandi che associano estensioni a tipi di file e tipi di file a file eseguibili, in questo modo:

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 è l'argomento qui - ovvero l'URL o il file che è possibile inviare al programma come input

Windows Vista e versioni successive, IE 7+

Il seguente script batch simula il clic su Imposta questi programmi come predefinito dall'applet del pannello di controllo Programmi predefiniti. Testato con Vista / 7 e IE 7 / IE 11.

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

Osservazioni

Qualsiasi applicazione browser web può registrarsi per apparire come client Internet nel menu Start. Questa visibilità, unita alla corretta registrazione per i tipi di file e di protocollo di un'applicazione, fornisce lo stato predefinito del browser di un'applicazione. Il browser Web predefinito viene utilizzato per l'avvio di URL arbitrari da qualsiasi parte del sistema.

Nota Le registrazioni esistenti [collegamento menu di avvio] vengono ignorate in Windows 7 e versioni successive. Questa registrazione è obsoleta a partire da Windows 7.

_{Fonte: come registrare un browser Internet o un client di posta elettronica con il menu Start di Windows}

­­

La struttura gerarchica del registro per le associazioni di file e protocolli ha la precedenza sui valori predefiniti per utente rispetto ai valori predefiniti a livello di macchina.

_{Fonte: programmi predefiniti}

Puoi aggiungere sotto due righe in un file bat

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

Dopo aver eseguito il pipistrello, riavviare / disconnettersi e riconnettersi poiché sopra due righe di comando si intende modificare i valori del registro.

I dettagli aditinali possono essere trovati qui

(Risolto) -Cant imposta Internet Explorer come browser predefinito! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

Non so come impostare il browser predefinito dalla riga di comando, ma è possibile impostarlo e applicarlo per il dominio tramite criteri di gruppo.

Ecco qualcosa per iniziare:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

Rilascia semplicemente il startper far funzionare il comando o il file batch.

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

Per Windows 8 (IE 10+) è facile lo script VBS:

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

Avvia la pagina IE per modificare IE come predefinito e simula il clic sul pulsante per accettare.