Come configuro Firefox tramite uno script?

Sto cercando di configurare le seguenti impostazioni di Firefox tramite uno script (VBS o batch)

• Pagina iniziale predefinita
• motore di ricerca predefinito
• disabilita l'aggiornamento automatico

È possibile?

Puoi farlo creando o manipolando i file delle preferenze di Mozilla con il tuo linguaggio di scripting preferito.

Per un elenco di preferenze che è possibile impostare tramite questi file, consultare le Preferenze di Mozilla e informazioni su: documentazione di configurazione , anche se quelle che corrispondono al tuo elenco sembrano essere: -

• browser.startup.homepage (Pagina iniziale predefinita)
• browser.search.defaultenginename (motore di ricerca predefinito)
• app.update.auto (abilita / disabilita l'aggiornamento automatico)

Tuttavia, a seconda del proprio ambiente, potrebbe essere meglio inviare le impostazioni tramite un componente aggiuntivo personalizzato (vedere i commenti XPI nella Guida breve alle Preferenze di Mozilla ) o tramite GPO con FirefoxADM o simili.

È possibile sovrascrivere le opzioni del browser privato in un file user.js nella cartella dei profili utente. Lo uso spesso per sovrascrivere alcune opzioni, ad esempio il pipelining. Firefox deve essere riavviato dopo aver aggiornato user.js. Se il file user.js non esiste, è necessario crearne uno.

per copiare / incollare letteralmente la parte della risposta che stavo cercando (win env.)

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

Inserisci

user_pref("browser.startup.homepage", "http://www.URL");

i miei tentativi di copiare su macchine remote con il percorso Get-Content / cat string.txt / "String" >>, sono terminati con immondizia che è stata inserita nel prefs.jsfile a causa dei caratteri di escape nella stringa.

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

Il thread è vecchio, ma voglio comunque condividere la mia soluzione. Spero che questo aiuti qualcuno. Abbiamo riscontrato un problema simile e volevamo aggiungere i certificati da Windows Store a Firefox. Quindi ho creato uno script per farlo. Ad ogni modo, puoi cambiarlo in base alle tue esigenze: basta aggiungere o rimuovere le righe in :: create cfg_file_name.cfg [...] e inserire ciò di cui hai bisogno, ad esempio per iniziare la homepage e così via. Ricorda di impostare ^ prima dell'ultimo), altrimenti non funzionerà! echo pref("browser.startup.homepage", "http://superuser.com"^);

Dalla versione 49 puoi farlo in questo modo:

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit