Come posso cambiare la lingua di tutte le diapositive di PowerPoint contemporaneamente?

Sebbene questo thread sia piuttosto vecchio, Microsoft non ha fornito alcuna soluzione che io conosca. Suggerisco un altro approccio per gli utenti Mac: apri la tua presentazione in Keynote, cambia la lingua dell'ortografia e possibilmente modifica l'intera presentazione, quindi esportala in PowerPoint.

Per cambiare facilmente la lingua dell'intero PowerPoint, aprire la scheda Visualizza e selezionare la vista Struttura .

Ora premi

• Ctrl+ Aper selezionare tutto.
• Strumenti → Lingua → Scegli la lingua da impostare.

Allo stesso modo, mentre hai tutto selezionato, puoi cambiare altre cose come caratteri, colori, ecc. Sebbene, in molti casi, ciò sia meglio fatto cambiando la diapositiva master, una presentazione che ha avuto molti editor può avere un sacco di set di formattazione "difficile" che si discosta dal master sottostante e deve essere ripristinato per essere coerente. Puoi anche reimpostare le singole diapositive sullo stile principale, ma ciò può comportare lo spostamento anche dei segnaposto, il che potrebbe essere indesiderabile in alcune situazioni.

PowerPoint 2013

• Visualizza → Contorno → seleziona tutte le diapositive (nel menu a sinistra) tramite Ctrl+ A.
• Rivedi → Lingua → Imposta lingua di prova ... → Scegli la lingua da impostare.

Per quanto mi riguarda, era necessario il riavvio di PowerPoint . Probabilmente perché ho anche cambiato la lingua di modifica :

• Rivedi → Lingua → Imposta lingua di prova ... → Preferenze lingua → Scegli lingue di modifica .

Utilizzando Powerpoint 2010 ho aperto il menu Struttura -

Selezionato tutto il testo (Ctrl + A), aperto il menu della lingua e impostato la mia lingua di correzione

E ha funzionato!

Il menu della lingua si trova nella scheda della barra multifunzione Revisione (dopo la scheda Presentazione e non visibile sullo screenshot).

Le risposte esistenti funzionano per il testo presente nella struttura. Sfortunatamente nel mio caso questo non ha riguardato una parte significativa del testo, inclusi figure, tabelle, ecc.

Questa macro ha risolto il problema per me:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

Il "msoLanguageIDEnglishUS" utilizzato nella macro sopra può essere sostituito da qualsiasi lingua desiderata. L'elenco completo delle lingue è disponibile in questo articolo

(Il merito va a Ganesh Kumar che ha pubblicato qui la macro originale . Ho aggiunto il supporto per il primo livello di raggruppamento delle forme. Per migliorarla ulteriormente, la macro può essere ricorsiva per cercare gruppi che contengono altri gruppi, ecc.)

Ho migliorato la risposta di Inigo per fornire una versione ricorsiva che modifica tutti gli elementi nella lingua desiderata.

Questa versione esaminerà ricorsivamente ogni forma che è un tipo di gruppo. Alcune sperimentazioni suggeriscono che msoGroupe msoSmartArtsono i tipi di gruppo: sentiti libero di aggiungere a quell'elenco se trovi altri tipi di forme che possono contenere oggetti di testo.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Basato sulle risposte di Inigo, Duncan, Maria e DomDev, funziona con forme, tabelle, gruppi, SmartArt, ora e in futuro:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

La versione di Duncan funziona bene per tutto tranne che per le tabelle. Ho trovato un altro codice che sembra funzionare anche con le tabelle: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

Oltre alla risposta fornita da Mastergalen e per rispondere ai commenti relativi al nuovo testo digitato:

Se noterai, quella lingua cambierà automaticamente ogni volta che inizi a digitare un nuovo testo (che è molto fastidioso), devi cambiare la lingua predefinita corrente per PowerPoint:

• assicurarsi che la finestra di PowerPoint sia una finestra attiva
• nel Windows Taskbar(sì, in realtà non in PowerPoint), controlla se Language barè visibile,
  • se non andare a Control Panel > Region and Language > Keyboards and Languages. Fare clic Change keybords..., passare alla Language barscheda e selezionare l' Docked in the taskbaropzione. (questo è da Win7, quindi potrebbe essere un po 'diverso in altre versioni).
• ora azione chiave: nella Language barbarra delle applicazioni, fai clic sul codice della lingua e passa a EN (se attualmente desideri utilizzare l'inglese in PowerPoint). D'ora in poi, tutto il nuovo testo in PowerPoint sarà nella lingua selezionata :-)
• se vuoi scrivere nella tua lingua originale, basta cambiarlo indietro.

Nel 2014 ho realizzato un componente aggiuntivo che funziona ancora bene in PowerPoint 2016. https://github.com/wobba/officeaddin/releases/tag/v1.0.1

Cerca le lingue usate e ti consente di cambiare tutto in una volta, eseguendo il ciclo.