In Outlook2010, c'è un modo per visualizzare i promemoria posticipati attualmente?

Esiste un modo in Outlook 2010 per visualizzare un elenco di elementi che sono attualmente posticipati? Ad esempio, diciamo che tra due settimane ho impostato un promemoria per il pop-up di venerdì per un importante pranzo di riunione il lunedì successivo (mi piace ricordarmi delle attività del lunedì prima del fine settimana). Quando il promemoria viene visualizzato venerdì, lo sospingo per tre giorni in modo che venga visualizzato di nuovo prima di pranzo lunedì. Quindi lunedì si gira e la mia memoria è confusa e sono un po 'paranoico che venerdì ho accidentalmente respinto il promemoria invece di posticiparlo correttamente. Posso ancora vedere l'appuntamento originale sul mio calendario, ma devo assicurarmi che il promemoria venga effettivamente visualizzato quando me lo aspetto, in modo da non perdere il mio incontro.

Esiste un modo in Outlook 2010 per visualizzare un elenco dei promemoria attualmente posticipati? Ciò sarebbe utile anche per quei casi in cui ho completato un'attività il cui promemoria avevo posticipato fino a tardi, e ora voglio richiamare il promemoria posticipato e annullarlo.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Se non si ha familiarità con VBA, consultare la pagina di spiegazione di Slipstick . Troverai informazioni su:

• impostazioni di sicurezza macro;
• dove inserire il codice (è possibile utilizzare un modulo normale con Inserisci | Modulo); e
• come creare un pulsante.

In base a questo post del forum Visualizza articoli posticipati, non è possibile visualizzare un elenco di articoli posticipati. Il post suggerisce che potresti essere in grado di vedere una quantità limitata di informazioni utili creando una vista personalizzata che visualizza alcuni dei campi di promemoria.

Prova a fare clic sulla scheda Calendario, seleziona Visualizza e cambia vista. Quindi selezionare Elenco. Questo sembra mostrare un elenco di tutti i promemoria.