Come posso aggiornare automaticamente Flash Player ogni volta che viene rilasciata una nuova versione?

Sommario:

Update Service Flash Player non viene eseguito su un programma affidabile, e non scarica e applicare gli aggiornamenti quando automaticamente non eseguito.

Data l'importanza di installare una versione aggiornata di Flash Player (per quelli di noi che non usano Chrome con il suo lettore integrato), vorrei trovare un modo per garantire che i nuovi aggiornamenti vengano prontamente rilevati e installato.

Quello che segue sono i dettagli dei miei sforzi per risolvere questo problema da solo ...

Appendice A: Servizio di aggiornamento di Flash Player

OK, molto tempo fa in Flash Player 11.2 (o giù di lì?) Adobe ha aggiunto il servizio di aggiornamento di Flash Player (FlashPlayerUpdateService.exe), avrebbe dovuto mantenere aggiornato Flash Player ...

• Al momento dell'installazione, FPUS è configurato per essere eseguito come un servizio Windows, con Start Type impostato su Manual.

• Un'attività pianificata (Adobe Flash Player Updater.job) viene aggiunta per avviare questo servizio ogni ora.

Fin qui tutto bene - questa configurazione evita di avere un servizio costantemente in esecuzione, ma si assicura che i controlli vengano eseguiti abbastanza spesso da catturare rapidamente eventuali aggiornamenti. Aggiornamento software di Google è configurato in modo simile, e che funziona bene ...

... Eppure, quando ho verificato la versione del mio Flash Player installato, ho scoperto che era l' 11.6.602.180 , che, basandosi sull'analisi dei timestamp dei file in, è C:\Windows\System32\Macromed\Flashstato aggiornato (o installato) l'ultimo martedì, il 12 marzo, 2013 --- 3/12/13, 5:00:08 pm .

Ho fatto questa osservazione giovedì, 25 aprile 2013 --- 25/04/13, 7:00:00 pm , e controllando il sito Web di Adobe ho scoperto che l'attuale versione di Flash Player era l' 11.7.700.169 .

È passato più di un mese dall'ultimo aggiornamento, con uno nuovo chiaramente disponibile sul sito Web ma senza alcuna indicazione che il controllo orario in esecuzione sul mio computer lo abbia notato o abbia intenzione di scaricarlo.

Appendice B: esecuzione manuale dell'aggiornamento di Flash Player

C'era una volta, correre ti darebbe una finestra con un pulsante Installa ; premendolo si scarica il programma di installazione per la versione corrente (automaticamente, senza aprire un browser) e lo si esegue, quindi si fa clic su quel programma di installazione ed è fatto. Era manuale, ma ha funzionato! Trovando la mia installazione attuale non aggiornata (consultare l'Appendice A), ho prima provato questo processo di aggiornamento manuale. Tuttavia...FlashUtil32_<version>_Plugin.exe -update plugin

• In esecuzione (nel mio caso, quello è ) ... presenta solo una finestra con un pulsante Download, facendo clic su quel pulsante Download si apre il mio browser all'URL https://get3.adobe.com/flashplayer/update/activex .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• In esecuzione (nel mio caso, quello è ) ... presenta solo una finestra con un pulsante Download, facendo clic su quel pulsante Download si apre il mio browser all'URL https://get3.adobe.com/flashplayer/update/plugin .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

Ho potuto continuare con la pagina di Download che mi ha mandato a, deselezionare la casella foistware ( "! McAfee Security Scan Plus libero"), download che installer (ActiveX, senza foistware: install_flashplayer11x32axau_mssd_aih.exe, Plugin, non foistware: install_flashplayer11x32au_mssd_aih.exe) & probabilmente ho un Flash aggiornato ... ma poi, qual è il punto del servizio di aggiornamento di Flash Player se devo scaricare manualmente ed eseguire un altro exe?

Epilogo

Da allora ho il sospetto che il servizio di aggiornamento sia intenzionalmente ostacolato per indirizzare i primi utenti alla pagina di download manuale. Se questo è vero, probabilmente non c'è soluzione a questo corto di scrivere il mio aggiornamento; spero di sbagliarmi.

Forse il programma di aggiornamento applica solo gli aggiornamenti nell'intervallo 11.6.x?

È sempre possibile utilizzare collegamenti diretti agli installatori, che trovo più affidabili: ActiveX ; Plugin .

Con questo file .bat proverà ad aggiornare o installare automaticamente Flash Player per Internet Explorer, Firefox (SeaMonkey ed ecc.), Basato su Chromium (Chrome, Opera 15+ ed ecc.):

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

È necessario scaricare wget qui e devi inserirlo nella stessa directory in cui è stato posizionato .bat.

Un esempio un po 'più avanzato scritto in Autoit .

Caratteristiche: controllo semplice per la nuova versione, se qui nessuna nuova versione, uscire dal programma senza scaricare il programma di installazione di Flash Player. Se il programma di installazione del download non è riuscito, mostra la finestra di messaggio con errore ed esce. Finestra del prompt dei comandi nascosta. Non ho bisogno di wget.

Dopo l'installazione Autoit ed Editor . Fare clic destro sul desktop-> Nuovo-> Autoit Script. Fare clic con il tasto destro su questo file creato-> Modifica. Ora dovresti vedere la finestra ScITE e la riga successiva "Aggiungi il tuo codice qui sotto" aggiungi questo codice:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Quindi nella finestra di SciTE premi Strumenti-> Costruisci o premi F7. Ora otterrai eseguibile autonomo nella stessa directory in cui era lo script Autoit.

Consiglio di creare una nuova cartella (con permesso di accesso in scrittura) per questo "programma di aggiornamento". È possibile aggiungere un collegamento a questo "programma di aggiornamento" per avviare anche.

Qui app per disinstallare flash player.

Voglio solo condividere il mio script batch con te, basta salvare questo pezzo di codice nel tuo blocco note e chiamarlo come Download_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************