Collegamenti InDesign: percorsi di conflitto tra Mac e PC

La mia azienda utilizza InDesign su Windows da anni. Quando creano "Link", vengono indirizzati a un'unità di rete, quindi il percorso del file inizia con una lettera di unità, ad esempio "N: ...". Recentemente abbiamo ottenuto iMac e i collegamenti non funzionano con loro poiché i percorsi Mac non iniziano con le lettere di unità.

Potremmo aggiornare manualmente tutti i collegamenti, ma questo è quasi impossibile perché sono migliaia di file. Inoltre, abbiamo ancora utenti Windows, quindi la modifica dei collegamenti causerebbe l'interruzione di tali computer. Non so se è possibile aggiornare a livello di codice i collegamenti, ma anche se fosse, dovrebbero essere cambiati in qualcosa che funziona sia su PC che su Mac.

Da quello che posso dire, non è saggio usare le unità di rete come siamo stati, ma non sono sicuro delle alternative.

C'è una soluzione rapida? In caso contrario, quali misure dobbiamo prendere per risolvere questo problema?

La soluzione di Adobe è utilizzare Adobe Bridge. Questa domanda a Stack Exchange / Graphic Design ha una buona discussione del problema.

Di fronte a questo problema "Collegamenti PC", gli utenti Mac di una società di prestampa eseguono il seguente Applescript per ricollegare il proprio file. Forse lo troverai utile.

global foundPaths, foundPathNames
set foundPathNames to {}
set foundPaths to {}
set missedLinks to "" -- name of links not found
tell application "Adobe InDesign CS5"
    activate
    -- choose pic folder
    set folderpath to (choose folder with prompt "Choose folder containing pictures:") as Unicode text
    tell document 1
        set missingLinks to every link whose status is link missing
        if missingLinks is not {} then
            set missingLinkNames to name of every link whose status is link missing
            set linkcount to count of items of missingLinkNames
            -- search for file recursively
            my checkforfile(folderpath, missingLinkNames, linkcount)
            set foundCount to count of items of foundPathNames
            -- see if file was found, and relink if so
            repeat with i from 1 to linkcount
                repeat with j from 1 to foundCount
                    if contents of item j of foundPathNames = contents of item i of missingLinkNames then
                        relink item i of missingLinks to alias (item j of foundPaths)
                        exit repeat
                    else if j = foundCount then
                        set missedLinks to missedLinks & (item i of missingLinkNames) & ", "
                    end if
                end repeat
            end repeat
            try -- in case there aren't any
                update (every link whose status is link out of date)
            end try
            if missedLinks = "" then
                display dialog "All links updated."
            else
                display dialog "The following links weren't found: " & return & (text 1 thru -3 of missedLinks)
            end if
        else
            display dialog "No links missing."
        end if
    end tell
end tell

on checkforfile(folderpath, fileNames, n)
    set theList to list folder file folderpath without invisibles
    repeat with anItem in theList
        set thePath to alias (folderpath & anItem) as Unicode text
        if thePath ends with ":" then
            set searchResult to my checkforfile(thePath, fileNames, n)
            if searchResult is false then
                return false
            end if
        else if contents of anItem is in fileNames then
            set end of foundPathNames to contents of anItem
            set end of foundPaths to thePath
            if (count of items of foundPaths) = n then
                return false
            end if
        end if
    end repeat
    return true
end checkforfile