Come calcolo il numero di mesi tra due date in Excel? [duplicare]

8

Ho due colonne su Microsoft Excel: F è la colonna con il servizio di data terminato; E è la colonna con l'inizio del servizio di data.

Come faccio a calcolare e segnalare il numero di mesi serviti per ogni persona?

microsoft-excel

— Terrance Drake
fonte

Comunicaci il risultato desiderato con (es.) 14.3.2014 - 12.7.2014: (a) 4 mesi (il 4 ° non è completo) o (b) 5 mesi (contando ogni mese toccato) o (c) 3 mesi (solo contare i mesi completi) o (d) 3,9 mesi.

— Guntbert,

1

La risposta qui è migliore di quella "originale" collegata a questa domanda

— Jayan,

16

La funzione DATEDIF ti fornisce esplicitamente il numero di mesi tra due date, arrotondando per eccesso

=DATEDIF(A2,B2,"m")

dove A2 è la prima delle due date

Se vuoi arrotondare al mese "più vicino" intero puoi usare questa versione

=DATEDIF(A2,B2+15,"m")

Se non ti interessa il giorno e qualsiasi data in gennaio a qualsiasi data in marzo è di 3 mesi, puoi utilizzare questa versione

=DATEDIF(A2-DAY(A2)+1,B2,"m")+1

— Barry Houdini
fonte

Funziona anche su Fogli Google.

— Adriano P

Puoi usare =(B2 - A1)/(365/12)se vuoi una risposta non arrotondata, considera che un mese dura mediamente 365/12 giorni

— aljgom

3

C'è un KB di Microsoft che tratta proprio questo argomento qui

Fornisce due soluzioni, a seconda se si desidera arrotondare i mesi verso il basso o verso l'alto.

Arrotondare:

=(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

Arrotondare:

=IF(DAY(LDate)>=DAY(EDate),0,-1)+(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

In entrambi i casi EDate è la cella contenente la data precedente e LDate è la cella contenente la data successiva.

— kenkh
fonte