Alla ricerca di un valore in Excel, restituendo sì o no

Ho una cartella di lavoro, con due fogli di lavoro separati. Voglio sapere se i valori che appaiono nel foglio di lavoro B compaiono anche nel foglio di lavoro A, in tal caso, voglio restituire un "SÌ". In caso contrario, voglio restituire un "NO".

(Esempio: il foglio di lavoro A è un elenco di libri scaduti. Il foglio di lavoro B è l'intera biblioteca).

Nel foglio di lavoro A, ho il seguente set di dati:

     A
1  AB123CD
2  EF456GH
3  IJ789KL
4  MN1011OP 

Nel foglio di lavoro B, ho il seguente set di dati:

      A           Overdue 
1  AB123CD           ?
2  QR1516ST          ?
3  EF456GH           ?
4  GT0405RK          ?
5  IJ789KL           ?
6  MN1011OP          ?

Come strutturerei la funzione per cercare correttamente se i valori esistono nella Tabella A?

Ho giocato con una combinazione di if (), vlookup () e match (), ma nulla sembra funzionare per più fogli di lavoro.

È possibile utilizzare la seguente funzione

=IFERROR(IF(MATCH(A1,Sheet1!$A:$A,0),"yes",),"no")

A partire dall'interno

Abbina, cerca nella colonna A del foglio1 per vedere se esiste un valore che corrisponde alla cella A1 del foglio corrente (foglio2). Se esiste una corrispondenza esatta, viene restituito il numero di riga.

L'istruzione if. Se match restituisce qualcosa (numero 1 o superiore), questo viene considerato come vero e restituisce "sì"

IFERROR. Se match non trova nulla, restituisce un errore na. Iferror rende questo ritorno l'ultimo "no"

VLOOKUP dovrebbe funzionare ...

=IF(ISNA(VLOOKUP(A1,Sheet1!$A:$A,1,false)),"NO","YES")

Se non viene trovata alcuna corrispondenza, VLOOKUP restituisce NA. Quindi vediamo se il suo risultato ISNA? Quindi restituire NO altrimenti SÌ

Puoi anche usare COUNTIFun'istruzione combinata con un IF:

=IF(COUNTIF(WorksheetA!$A:$A,WorksheetB!$A1)>0,"Yes","No")

Questo conta il numero di volte in cui i contenuti della cella A1 vengono trovati nella colonna A del primo foglio di lavoro. Se il numero è superiore a 0, l'articolo è nell'elenco e pertanto restituiamo un "Sì", altrimenti, se COUNTIFrestituisce uno 0, l'articolo non è stato trovato e restituiamo un "No".

Uso COUNTIFquotidianamente per identificare gli elementi in un elenco e in un altro (oltre ai duplicati).