Scorciatoia da tastiera per passare da un foglio all'altro in Excel

Excel 2007 ha una scorciatoia da tastiera che passa da un foglio di lavoro all'altro?

Ctrl+ PgUpper spostarsi a sinistra.

Ctrl+ PgDnper spostarsi a destra.

Macro VBA e scorciatoia da tastiera personalizzata per attivare il primo o l'ultimo foglio

Se si desidera che una scorciatoia da tastiera effettiva passi al primo o all'ultimo foglio di lavoro, inserire questo codice in un modulo nella cartella di lavoro "PERSONALE":

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

Vai alla scheda Sviluppatore> Macro. Cerca queste macro (ToFirstSheet e ToLastSheet). Selezionane uno, fai clic su Opzioni e assegna una scorciatoia da tastiera. Fai lo stesso per l'altro.

Salvandolo nella cartella di lavoro "PERSONALE" sarà disponibile in qualsiasi file Excel.

Scorciatoie da tastiera integrate per attivare il foglio precedente o successivo

Per saltare un foglio di lavoro a sinistra oa destra è possibile utilizzare queste scorciatoie da tastiera predefinite:

Ctrl+PgUp

Ctrl+PgDn

Macro VBA per attivare il foglio precedente o successivo

Ecco come ottenere lo stesso risultato usando VBA prova questo:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

Funzioni VBA per restituire il foglio precedente o successivo

Utilizzare questa funzione se si desidera ottenere l'oggetto del foglio di lavoro precedente o successivo:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

Utilizzare le funzioni in questo modo:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

È inoltre possibile utilizzare i tasti di scelta rapida per accedere alla Gofinestra di dialogo. È quindi possibile digitare qualcosa di simile foo!A1per navigare nella cella in alto a sinistra nel foglio chiamato "pippo". Mentre pagina su e pagina giù sono generalmente più veloci. Se si dispone di un numero elevato (ad es. 20+) di fogli con nome, questo potrebbe essere più veloce. Go funziona anche se hai chiamato le tabelle nei tuoi fogli.

Premendo F5 normalmente si apre la Gofinestra di dialogo.