Impedisci che gli aggiornamenti nag di Windows 10 vengano installati su Windows 7

3

Durante il loro blitz su Windows 10, alcuni esponenti della Microsoft hanno pensato che sarebbe stata un'ottima idea inviare messaggi di marketing "fastidiosi" agli utenti di Windows 7, con il pretesto di Aggiornamenti di Windows. A peggiorare le cose, ci sono voluti alcuni tentativi per farlo bene, risultando in diverse patch correlate che potrebbero essere mostrate.

Quando installo nuovi computer Windows 7 SP1 da zero (e sì, ci sono ancora motivi legittimi per farlo), qual è il modo più rapido e semplice per impedire che questi "aggiornamenti" indesiderati vengano mai applicati?

windows-7 windows-update windows-10-upgrade

— rkagerer
fonte

3

Questo post non vuole essere una critica a Windows 10 o scatenare una discussione sul perché dovrei aggiornare. Sto semplicemente cercando un modo per disabilitare permanentemente i fastidi.

— rkagerer,

2

Ho trovato alcuni passaggi manuali qui e qui e ho tentato di automatizzarli usando lo script sporco e non così veloce di seguito (basato su questo ). Ma ci vuole più di mezz'ora per correre e sto lasciando la domanda aperta nella speranza che qualcuno possa suggerire una soluzione più conveniente.

Dim msg
msg = "Searching for and hiding six Windows Updates related to Windows 10 nagging." & vbCrLf
msg = msg & "Be patient; this may take a LONG time during which nothing appears to happen."
msg = msg & " You can tell the script is still running by using Task Manager and looking for wscript.exe"
Wscript.echo msg

Dim hideupdates(5)
hideupdates(0) = "KB3035583"
hideupdates(1) = "KB2952664"
hideupdates(2) = "KB2976978"
hideupdates(3) = "KB3021917"
hideupdates(4) = "KB3044374"
hideupdates(5) = "KB2990214"

Dim status(5)
For i = 0 to UBound(status)
  status(i) = "notfound"
Next

set updateSession = createObject("Microsoft.Update.Session")
set updateSearcher = updateSession.CreateupdateSearcher()

Set searchResult = updateSearcher.Search("IsInstalled=0 and Type='Software'")

dim results
Set results = searchResult.Updates
For i = 0 To results.Count-1
  set update = results.Item(i)
  For j = LBound(hideupdates) To UBound(hideupdates)
    if instr(1, update.Title, hideupdates(j), vbTextCompare) > 0 then
      if update.IsHidden then
        status(j) = "alreadyhidden"
      else
        update.IsHidden = True
        status(j) = "hidden"
      end if
    end if
  Next
Next

Dim alreadyhidden
Dim hidden
Dim notfound

for i = 0 to UBound(status)
  Select Case status(i)
    Case "alreadyhidden"
      alreadyhidden = alreadyhidden & hideupdates(i) & vbCrLf
    Case "notfound"
      notfound = notfound & hideupdates(i) & vbCrLf
    Case "hidden"
      hidden = hidden & hideupdates(i) & vbCrLf
  End Select
next
msg = "Hid these Windows 10 related updates:" & vbCrLf
msg = msg & hidden & vbCrLf
msg = msg & "These ones were already hidden:" & vbCrLf
msg = msg & alreadyhidden & vbCrLf
msg = msg & "These ones were not found on this machine:" & vbCrLf
msg = msg & notfound

Wscript.echo msg

— rkagerer
fonte

0

Quota rkagerer "Qual è il modo più rapido e semplice per impedire che questi" aggiornamenti "indesiderati non vengano mai applicati?" Se stai eseguendo una nuova installazione di

"Deseleziona Aggiornamenti consigliati (Opzionale) nelle impostazioni di aggiornamento di Windows."

Si legge Dammi aggiornamenti consigliati allo stesso modo in cui ricevo aggiornamenti importanti. Successivamente è possibile controllare singolarmente gli aggiornamenti consigliati quelli che si desidera installare, se presenti. Non consiglio di installare tutti gli aggiornamenti consigliati lanciati da MS. Recentemente ha creato più casino che bene.

— dccet
fonte