In Excel (o numeri) quale formula può calcolare la quantità di giorni in un determinato mese in 2 date

4

Se un ospite è arrivato il 24 agosto e se ne è andato il 4 settembre, qual è la formula (s) per calcolare quante notti vengono spese in agosto e quante notti vengono spese a settembre?

microsoft-excel iwork-numbers

— tom
fonte

Vuoi includere il 4 settembre o escluderlo nel conteggio delle notti ??

— Gary's Student

Il soggiorno può estendersi fino a tre mesi di calendario?

— fixer1234

3

Di seguito è riportata una tabella per dividere per mese il numero di notti indipendentemente dal numero di mesi inclusi:

Si noti che anche se nella prima riga appaiono solo i nomi dei mesi, questi sono in realtà date: i primi giorni dei mesi formattati per mostrare solo il nome del mese ("mmmm")

La formula nella tabella è:
=NOT(OR(D$1>$B2,EOMONTH(D$1,0)<$A2))*(MIN(EOMONTH(D$1,0)+1,$B2)-MAX(D$1,$A2))

NOT(OR(D$1>$B2,EOMONTH(D$1,0)<$A2)) è decidere se la permanenza corrente e il mese si sovrappongono
MIN(EOMONTH(D$1,0)+1,$B2)-MAX(D$1,$A2) è la durata del soggiorno

I calcoli sono fatti come l'ho trovato negli hotel: la notte è conteggiata al giorno precedente (la riga 4 è una notte in agosto) e un giorno il soggiorno non è conteggiato come una notte (vedi riga 5)

— Máté Juhász
fonte

2

Suggerimento; Sposta la formula completa dopo in the table su una singola riga, rende più facile la lettura.

— Hannu

Funziona bene per me, grazie mille!

— tom

3

Supponendo che la data di arrivo sia in A1 e la data di check-out è in B1 poi via C1 devi mettere:

=IF(EOMONTH(A1,0)<B1,CONCATENATE((EOMONTH(A1,0)-A1)," and ",B1-A1-(EOMONTH(A1,0)-A1)-1),B1-A1)

spiegazione:

IF ( 
    EOMONTH(A1,0)<B1 //If last day of month of arrival is before the checkout date then
        CONCATENATE( //concatenate days of first month "and" days of next month
                     (EOMONTH(A1,0)-A1),
                     " and ",
                     B1-A1-(EOMONTH(A1,0)-A1)-1
                    )
        B1-A1 //Else, simply substract checkout date from arrival date.

— jcbermu
fonte