Come usare l'ordinamento su un comando di stampa awk?

Ho un paio di comandi in uno script awk che sto scrivendo:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2}

Quali uscite:

Here are some players and their numbers, sorted by last name
Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55

Come posso usare il sortcomando nel mio script awk per ordinare SOLO i giocatori e i loro numeri?

puoi aggiungere | sort -k2al tuo comando. Questo ordinerà alfabeticamente in base alla seconda colonna.

Esempio:

$ echo "Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55" | sort -k2

risultati in

Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Anche se non lo consiglierei (data la relativa semplicità di sorteseguire il piping del risultato tramite un comando esterno ), puoi farlo almeno con le versioni recenti di GNU awk (almeno 4.0 IIRC), come descritto in Ordinamento di valori di array e indici con gawk

Ecco come potresti implementarlo, supponendo che tu abbia i dati in un array associativo in cui si trova l'indice Firstname Lastname. Per prima cosa devi definire una funzione di confronto personalizzata che divide l'indice, poi confronta prima Lastname(come un pareggio) ad Firstnamees.

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

Ora puoi usare il PROCINFO["sorted_in"]metodo di ordinamento degli array menzionato nei commenti di @zwets

PROCINFO["sorted_in"] = "mycmp";
for(i in a) print i, a[i];

Mettendolo insieme

#!/usr/bin/gawk -f

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

{
  a[$1" "$2] = $3;
}

END {
  PROCINFO["sorted_in"] = "mycmp";
  for(i in a) print i, a[i];
}

test:

$ ./namesort.awk yourfile
Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Nelle versioni precedenti o precedenti di awk, la soluzione migliore potrebbe essere quella di archiviare i dati indicizzati Lastname Firstnameinvece, ordinare con il convenzionale asorti, quindi dividere e scambiare i campi degli indici mentre si attraversa l'array per stamparlo:

awk '
  {a[$2" "$1]=$3} 
  END {
    n=asorti(a,b); for (i=1;i<=n;i++) {split(b[i],s); print s[2], s[1], a[b[i]]}
}' yourfile

Per utilizzare sortsolo il secondo campo separato da spazi bianchi, utilizzare il tasto -k2,2:

... | sort -k2,2

per impostazione predefinita sortfa l'ordinamento lessicografico.

Si noti che, se non si menziona l'ultimo campo per la chiave di ordinamento, ad esempio se si utilizza semplicemente, -k2è possibile che non si ottenga il risultato desiderato, poiché ciò sortcorrisponderà a tutti i campi a partire dal secondo.

Controlla anche man sort.

Provare

awk -f myscript.awk | sort -k2

Dove myscript.awk contiene comandi puramente awk.

Se il tuo script reale è uno script di shell, hai diverse opzioni tra cui

• Uscita del tubo attraverso l'ordinamento. ./myscript.bash | sort -k2

• Riscrivi il codice come funzione all'interno dello script
  anziché

  $ cat t1
  #!/bin/bash
  for i in 2 4 3 1 5;
  do
    echo $i
  done
  
  $ ./t1
  2
  4
  3
  1
  5
  

  Fare

  $ cat t2
  #!/bin/bash
  function foo {
    for i in 2 4 3 1 5;
    do
      echo $i
    done
  }
  foo | sort
  
  $ ./t2
  1
  2
  3
  4
  5
  

Ma nota che puoi anche applicare l'ordinamento alla struttura do ... done invece di creare una funzione.

    do
       echo $i
    done | sort

Per ordinare i dati da stampare:

• Supponiamo di voler stampare il 2 ° campo (spazi separati) utilizzare questo:

  awk '{print $2}' data.txt | sort
  

  per esempio:

  $cat>data.txt
  1 Kedar 20
  2 Amit 30
  3 Rahul 21
  ^C
  
  $awk '{print $2}' | sort
  Amit
  Kedar
  Rahul
  

• Se vuoi stampare tutto il tuo data.txtma ordinato sulla colonna 2, quindi:

  $awk '{print}'|sort -k2
  2 Amit 30
  1 Kedar 20
  3 Rahul 21
  

Usa questa logica (s) nel tuo requisito.

È possibile utilizzare man sortper le funzionalità più interessanti di sort.

che dire di seguito:

 awk 'BEGIN{str="1\n2\n3\n4"; system("echo -e \""str"\" | sort -r")}'

funziona quando ho provato.

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2"}

Per ordinare l'output in un file:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2 > sortedFile"}