completamento della scheda zsh su una riga vuota

12

Vorrei un tcsh'ism che non sono stato in grado di trovare: su una riga vuota senza contenuto, voglio premere il tasto tab e vedere l'equivalente di un ls. Vale a dire che voglio

$ <tab>

fare qualcos'altro quindi dandomi un \ t. Ho trovato risorse fantastiche per il completamento del comando, ma non per questo caso di base. Qualsiasi aiuto su questo sarebbe fantastico! Grazie.

shell configuration zsh

— kristopolous
fonte

8

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

— John Eikenberry
fonte

Molto pulito. Sarebbe possibile in qualche modo nascondere di nuovo l'elenco? Tab-to-show quindi tab-to-hide sarebbe bello.

— Parker Coates,

Grazie John, ho trovato la soluzione e adattato qui stackoverflow.com/questions/28729851/...~~V~~singular~~3rd

— lolesque

7

Il comportamento Taball'inizio di una riga è controllato dallo stile . Tuttavia, ci sono solo due comportamenti supportati:insert-tab

completamento come al solito, sotto zstyle ':completion:*' insert-tab false
inserire una scheda, sotto zstyle ':completion:*' insert-tab true
l'uno o l'altro sotto zstyle ':completion:*' insert-tab pending[=N]

Se vuoi solo completare i comandi in quella posizione, zstyle ':completion:*' insert-tab truelo farà. Se vuoi qualcosa di diverso, come elencare i file nella directory corrente, dovrai modificarli _main_complete.

Una discussione recente sulla lista di zsh-worker discussa insert-tab.

— Gilles 'SO- smetti di essere malvagio'
fonte

fantastico! Con _main_complete sembra che tu stia facendo riferimento da qualche parte nel codice C? Mi dispiace per la domanda stupida, ma dove sarebbe trovata?

1

@ user535759: No, _main_completefa parte del codice zsh che implementa il completamento. Si trova nell'albero Completion/Base/Core/_main_completedei sorgenti, in genere installato in una posizione come /usr/share/zsh/functions/Completion/Base/_main_complete.

— Gilles 'SO-smetti di essere malvagio'

@llua La modifica dello stile associato -command-non causa <Tab> per elencare i file nella directory corrente. Tutto quello che hai fatto è limitare le corrispondenze per omettere i nomi dei comandi. Ma sono elencate solo le cose che verrebbero completate in questa posizione, quindi non i file nella directory corrente (solo directory ed eseguibili a seconda di autocde PATH).

— Gilles 'SO- smetti di essere malvagio' il

3

Ecco l'implementazione completa dell'autolista di tcsh in zsh, quando si preme la scheda su una riga vuota

% <TAB>

Ecco qui:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Se vuoi emulare tcsh più da vicino, aggiungi anche questo al tuo .zshrc:

unsetopt always_last_prompt       # print completion suggestions above prompt

— ILUXA
fonte

2

Ho scritto questo widget zsh che migliora l'uso di TAB, non solo su una riga vuota, ma anche mentre si digita un comando.

Elencherà i file su una riga di comando vuota e nel mezzo di qualsiasi comando.
Elencherà le directory su una riga di comando vuota.
Elencherà gli eseguibili su una riga di comando vuota.

Può essere configurato per anteporre "cd" o "./" in quei casi con una variabile globale.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA

— nachoparker
fonte