Nota : ora mantengo un lsofwrapper che combina entrambi gli approcci descritti qui e aggiunge anche informazioni per i peer delle connessioni TCP loopback su https://github.com/stephane-chazelas/misc-scripts/blob/master/lsofc
Linux-3.3 e versioni successive.
Su Linux, dalla versione 3.3 del kernel (e purché la UNIX_DIAGfunzionalità sia integrata nel kernel), il peer di un determinato socket di dominio unix (include socketpairs) può essere ottenuto usando una nuova API basata su netlink .
lsof dalla versione 4.89 può utilizzare quell'API:
lsof +E -aUc Xorg
Elencherà tutti i socket di dominio Unix che hanno un processo il cui nome inizia Xorgalle estremità in un formato simile a:
Xorg 2777 root 56u unix 0xffff8802419a7c00 0t0 34036 @/tmp/.X11-unix/X0 type=STREAM ->INO=33273 4120,xterm,3u
Se la tua versione di lsofè troppo vecchia, ci sono alcune altre opzioni.
L' ssutilità (da iproute2) utilizza la stessa API per recuperare e visualizzare informazioni sull'elenco dei socket di dominio unix sul sistema, comprese le informazioni sui peer.
I socket sono identificati dal loro numero di inode . Si noti che non è correlato all'inode del filesystem del file socket.
Ad esempio in:
$ ss -x
[...]
u_str ESTAB 0 0 @/tmp/.X11-unix/X0 3435997 * 3435996
dice che il socket 3435997 (che era associato al socket ABSTRACT /tmp/.X11-unix/X0) è collegato al socket 3435996. L' -popzione può dirti quale processo (i) ha quel socket aperto. Lo fa facendo alcuni readlinksecondi /proc/$pid/fd/*, quindi può farlo solo sui processi che possiedi (a meno che tu non lo sia root). Ad esempio qui:
$ sudo ss -xp
[...]
u_str ESTAB 0 0 @/tmp/.X11-unix/X0 3435997 * 3435996 users:(("Xorg",pid=3080,fd=83))
[...]
$ sudo ls -l /proc/3080/fd/23
lrwx------ 1 root root 64 Mar 12 16:34 /proc/3080/fd/83 -> socket:[3435997]
Per scoprire quale processo (i) ha 3435996, puoi cercare la sua voce nell'output di ss -xp:
$ ss -xp | awk '$6 == 3435996'
u_str ESTAB 0 0 * 3435996 * 3435997 users:(("xterm",pid=29215,fd=3))
Puoi anche usare questo script come wrapper lsofper mostrare facilmente le informazioni rilevanti lì:
#! /usr/bin/perl
# lsof wrapper to add peer information for unix domain socket.
# Needs Linux 3.3 or above and CONFIG_UNIX_DIAG enabled.
# retrieve peer and direction information from ss
my (%peer, %dir);
open SS, '-|', 'ss', '-nexa';
while (<SS>) {
if (/\s(\d+)\s+\*\s+(\d+) ([<-]-[->])$/) {
$peer{$1} = $2;
$dir{$1} = $3;
}
}
close SS;
# Now get info about processes tied to sockets using lsof
my (%fields, %proc);
open LSOF, '-|', 'lsof', '-nPUFpcfin';
while (<LSOF>) {
if (/(.)(.*)/) {
$fields{$1} = $2;
if ($1 eq 'n') {
$proc{$fields{i}}->{"$fields{c},$fields{p}" .
($fields{n} =~ m{^([@/].*?)( type=\w+)?$} ? ",$1" : "")} = "";
}
}
}
close LSOF;
# and finally process the lsof output
open LSOF, '-|', 'lsof', @ARGV;
while (<LSOF>) {
chomp;
if (/\sunix\s+\S+\s+\S+\s+(\d+)\s/) {
my $peer = $peer{$1};
if (defined($peer)) {
$_ .= $peer ?
" ${dir{$1}} $peer\[" . (join("|", keys%{$proc{$peer}})||"?") . "]" :
"[LISTENING]";
}
}
print "$_\n";
}
close LSOF or exit(1);
Per esempio:
$ sudo that-lsof-wrapper -ad3 -p 29215
COMANDO PID UTENTE TIPO FD MISURA DISPOSITIVO / OFF NOME NOME
xterm 29215 stephane 3u unix 0xffff8800a07da4c0 0t0 3435996 type = STREAM <-> 3435997 [Xorg, 3080, @ / tmp / .X11-unix / X0]
Prima di Linux-3.3
La vecchia API Linux per recuperare le informazioni sui socket unix è tramite il /proc/net/unixfile di testo. Elenca tutti i socket di dominio Unix (inclusi socketpairs). Il primo campo lì dentro (se non nascosto ai non superutenti con il kernel.kptr_restrictparametro sysctl) come già spiegato da @Totor contiene l'indirizzo del kernel di una unix_sockstruttura che contiene un peercampo che punta al peer corrispondente unix_sock. È anche ciò che lsofgenera la DEVICEcolonna su un socket Unix.
Ora ottenere il valore di quel peercampo significa poter leggere la memoria del kernel e conoscere l'offset di quel peercampo rispetto unix_sockall'indirizzo.
Sono già state fornite diverse soluzioni basate gdbsu e systemtapbasate ma richiedono gdb/ systemtape simboli di debug del kernel Linux per il kernel in esecuzione che non è generalmente il caso dei sistemi di produzione.
L'hardcoding dell'offset non è in realtà un'opzione in quanto varia con la versione del kernel.
Ora possiamo usare un approccio euristico per determinare l'offset: chiedi al nostro strumento di creare un manichino socketpair(quindi conosciamo l'indirizzo di entrambi i peer) e cercare l'indirizzo del peer attorno alla memoria all'altra estremità per determinare l'offset.
Ecco uno script di prova di concetto che fa proprio questo usando perl(testato con successo con i kernel 2.4.27 e 2.6.32 su i386 e 3.13 e 3.16 su amd64). Come sopra, funziona come un wrapper lsof:
Per esempio:
$ that-lsof-wrapper -aUc nm-applet
COMANDO PID UTENTE TIPO FD MISURA DISPOSITIVO / OFF NOME NOME
nm-applet 4183 stephane 4u unix 0xffff8800a055eb40 0T0 36888 type = STREAM -> 0xffff8800a055e7c0 [dbus-daemon, 4190, @ / tmp / dbus-AiBCXOnuP6]
nm-applet 4183 stephane 7u unix 0xffff8800a055e440 0T0 36890 type = STREAM -> 0xffff8800a055e0c0 [Xorg, 3080, @ / tmp / .X11-unix / X0]
nm-applet 4183 stephane 8u unix 0xffff8800a05c1040 0t0 36201 type = STREAM -> 0xffff8800a05c13c0 [dbus-daemon, 4118, @ / tmp / dbus-
yxxNr3nC1nYnc1kY unix 0xffff8800a055d080 0T0 36219 type = STREAM -> 0xffff8800a055d400 [dbus-daemon, 4118, @ / tmp / dbus-yxxNr1NkYC]
nm-applet 4183 stephane 12u unix 0xffff88022e0dfb80 0T0 36221 type = STREAM -> 0xffff88022e0df800 [dbus-daemon, 2268, / var / run / dbus / system_bus_socket]
nm-applet 4183 stephane 13u unix 0xffff88022e0f80c0 0t0 37025 type = STREAM -> 0xffff88022e29ec00 [dbus-daemon, 2268, / var / run / dbus / system_bus_socket]
Ecco la sceneggiatura:
#! /usr/bin/perl
# wrapper around lsof to add peer information for Unix
# domain sockets. needs lsof, and superuser privileges.
# Copyright Stephane Chazelas 2015, public domain.
# example: sudo this-lsof-wrapper -aUc Xorg
use Socket;
open K, "<", "/proc/kcore" or die "open kcore: $!";
read K, $h, 8192 # should be more than enough
or die "read kcore: $!";
# parse ELF header
my ($t,$o,$n) = unpack("x4Cx[C19L!]L!x[L!C8]S", $h);
$t = $t == 1 ? "L3x4Lx12" : "Lx4QQx8Qx16"; # program header ELF32 or ELF64
my @headers = unpack("x$o($t)$n",$h);
# read data from kcore at given address (obtaining file offset from ELF
# @headers)
sub readaddr {
my @h = @headers;
my ($addr, $length) = @_;
my $offset;
while (my ($t, $o, $v, $s) = splice @h, 0, 4) {
if ($addr >= $v && $addr < $v + $s) {
$offset = $o + $addr - $v;
if ($addr + $length - $v > $s) {
$length = $s - ($addr - $v);
}
last;
}
}
return undef unless defined($offset);
seek K, $offset, 0 or die "seek kcore: $!";
my $ret;
read K, $ret, $length or die "read($length) kcore \@$offset: $!";
return $ret;
}
# create a dummy socketpair to try find the offset in the
# kernel structure
socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC)
or die "socketpair: $!";
$r = readlink("/proc/self/fd/" . fileno(Rdr)) or die "readlink Rdr: $!";
$r =~ /\[(\d+)/; $r = $1;
$w = readlink("/proc/self/fd/" . fileno(Wtr)) or die "readlink Wtr: $!";
$w =~ /\[(\d+)/; $w = $1;
# now $r and $w contain the socket inodes of both ends of the socketpair
die "Can't determine peer offset" unless $r && $w;
# get the inode->address mapping
open U, "<", "/proc/net/unix" or die "open unix: $!";
while (<U>) {
if (/^([0-9a-f]+):(?:\s+\S+){5}\s+(\d+)/) {
$addr{$2} = hex $1;
}
}
close U;
die "Can't determine peer offset" unless $addr{$r} && $addr{$w};
# read 2048 bytes starting at the address of Rdr and hope to find
# the address of Wtr referenced somewhere in there.
$around = readaddr $addr{$r}, 2048;
my $offset = 0;
my $ptr_size = length(pack("L!",0));
my $found;
for (unpack("L!*", $around)) {
if ($_ == $addr{$w}) {
$found = 1;
last;
}
$offset += $ptr_size;
}
die "Can't determine peer offset" unless $found;
my %peer;
# now retrieve peer for each socket
for my $inode (keys %addr) {
$peer{$addr{$inode}} = unpack("L!", readaddr($addr{$inode}+$offset,$ptr_size));
}
close K;
# Now get info about processes tied to sockets using lsof
my (%fields, %proc);
open LSOF, '-|', 'lsof', '-nPUFpcfdn';
while (<LSOF>) {
if (/(.)(.*)/) {
$fields{$1} = $2;
if ($1 eq 'n') {
$proc{hex($fields{d})}->{"$fields{c},$fields{p}" .
($fields{n} =~ m{^([@/].*?)( type=\w+)?$} ? ",$1" : "")} = "";
}
}
}
close LSOF;
# and finally process the lsof output
open LSOF, '-|', 'lsof', @ARGV;
while (<LSOF>) {
chomp;
for my $addr (/0x[0-9a-f]+/g) {
$addr = hex $addr;
my $peer = $peer{$addr};
if (defined($peer)) {
$_ .= $peer ?
sprintf(" -> 0x%x[", $peer) . join("|", keys%{$proc{$peer}}) . "]" :
"[LISTENING]";
last;
}
}
print "$_\n";
}
close LSOF or exit(1);