awk si assegna a più variabili contemporaneamente

Sto cercando di estrarre due valori numerici da una stringa e assegnarli alle variabili usando awk( gawkè quello che sto usando specificamente). Voglio estrarre i numeri di versione maggiore e minore da una stringa di versione tmux in awkvariabili, ad esempio:

• input tmux 2.8:; maj == 2emin == 8
• input tmux 1.9a:; maj == 1emin == 9
• input tmux 2.10:; maj == 2emin == 10

Supponendo che il mio input provenga da tmux -Vstdin, al momento ho il seguente:

tmux -V | awk '{
                  maj = +gensub(/([0-9]+)\..*/, "\\1", "g", $2);
                  min = +gensub(/.*\.([0-9]+).*/, "\\1", "g", $2);
                  # ...do something with maj and min...
               }'

Funziona, ma come molti utenti di tmux sanno, usare if-shellnel .tmux.conffile (dove spero di usare questa roba) può facilmente portare a righe molto lunghe nel file di configurazione, quindi mi chiedo se c'è un modo per combinare queste due variabili assegnazioni in un'istruzione per risparmiare spazio ... o in qualsiasi altro modo per raccogliere queste due variabili dall'input e risparmiare spazio.

Sto pensando a qualcosa del tipo:

awk '{ maj, min = +gensub(/([0-9]+)\.([0-9]+).*/, "\\1 \\2", "g", $2); }'

... un po 'come in Python, ma quella particolare sintassi non esiste awk. C'è qualcos'altro che è possibile?

Nota che la leggibilità non è davvero un problema, ma solo la lunghezza.

Nota che gensubè gawkun'estensione, non funzionerà con nessun'altra awkimplementazione. Si noti inoltre che l' +operatore unario non impone la conversione numerica in tutte le awkimplementazioni, l'utilizzo + 0è più portabile.

Qui puoi fare:

tmux -V | awk -F '[ .]' '{maj = $2+0; min = $3+0; print maj, min}'

Se non ti dispiace usare le awkestensioni GNU , puoi anche fare:

tmux -V | awk -v FPAT='[0-9]+' '{maj = $1; min = $2; print maj, min}'

Dato che stai usando GNU awk, puoi usare il modulo 3-arg di match()per memorizzare più gruppi di acquisizione:

awk '
    match($0, /([0-9]+)\.([0-9]+)/, m) {maj=m[1]; min=m[2]; print maj, min}
' <<END
tmux 2.8
tmux 1.9a
tmux 2.10
END

2 8
1 9
2 10

https://www.gnu.org/software/gawk/manual/html_node/String-Functions.html

Puoi dividere la versione in un array:

awk '{ split($2, ver, /[.a-z]/) }'

quindi utilizzare ver[1]invece di maj, ver[2]anziché min.

L'aggiunta a-zal separatore rimuove qualsiasi lettera minuscola dal numero di versione. (Le altre soluzioni sono migliori qui poiché estraggono esplicitamente i numeri.)

Un altro utente ha pubblicato questa risposta, che è stata successivamente eliminata. Ho pensato che fosse utile:

Utilizzando la split()funzione, dividere la stringa di versione in un array ver, quindi accedere ver[1]e ver[2]anziché e maje min, rispettivamente (o semplicemente archiviare i valori in tali variabili):

tmux -V | awk '{ split($2, ver, /[.a-z]/); print ver[1], ver[2] }'

Il vantaggio qui è che split()non è gawkun'estensione (anche se il suo quarto argomento opzionale sepsè).