Come posso cambiare la schermata iniziale o introduttiva di Vim?

Quando avvio Vim senza alcun file, vedo sempre questo:

              VIM - Vi IMproved

               version 7.4.580
           by Bram Moolenaar et al.
 Vim is open source and freely distributable

        Become a registered Vim user!
type  :help register<Enter>   for information

type  :q<Enter>               to exit
type  :help<Enter>  or  <F1>  for on-line help
type  :help version7<Enter>   for version info

Come posso cambiarlo?

In particolare, vorrei inserire qui l'output di un comando shell ( fortune).

So di vim-startify ; ma non ho bisogno di tutte quelle funzionalità. Voglio solo mostrare un po 'di testo semplice ...

In realtà la risposta è in startify. In startify.vim intorno alla linea 15 possiamo vedere

 autocmd VimEnter * nested
\ if !argc() && (line2byte('$') == -1) && (v:progname =~? '^[-gmnq]\=vim\=x\=\%[\.exe]$')
\ | if get(g:, 'startify_session_autoload') && filereadable('Session.vim')
\ | source Session.vim
\ | else
\ | call startify#insane_in_the_membrane()
\ | endif
\ | endif
\ | autocmd! startify VimEnter

Quindi la cosa rilevante è il VimEntercomando automatico che si chiama " dopo aver fatto tutto il materiale di avvio ".
Di seguito viene ifverificato se si tratta di una sessione vuota (controllando argomenti simili filename). Fondamentalmente puoi mettere il tuo codice al posto del secondo if, che è il codice specifico di startify.

Ecco il codice da cui ho estratto vim-startify; le parti chiave stanno creando un nuovo buffer su VimEnterautocmd, inserendo un po 'di testo in questo, e quindi mappando iper avviare un nuovo buffer e quindi passare alla modalità di inserimento.

Ho messo il seguito in un piccolo plugin che aggiunge alcune impostazioni e simili, ma il concetto di base è esattamente lo stesso.

fun! Start()
    " Don't run if: we have commandline arguments, we don't have an empty
    " buffer, if we've not invoked as vim or gvim, or if we'e start in insert mode
    if argc() || line2byte('$') != -1 || v:progname !~? '^[-gmnq]\=vim\=x\=\%[\.exe]$' || &insertmode
        return
    endif

    " Start a new buffer ...
    enew

    " ... and set some options for it
    setlocal
        \ bufhidden=wipe
        \ buftype=nofile
        \ nobuflisted
        \ nocursorcolumn
        \ nocursorline
        \ nolist
        \ nonumber
        \ noswapfile
        \ norelativenumber

    " Now we can just write to the buffer, whatever you want.
    call append('$', "")
    for line in split(system('fortune -a'), '\n')
        call append('$', '        ' . l:line)
    endfor

    " No modifications to this buffer
    setlocal nomodifiable nomodified

    " When we go to insert mode start a new buffer, and start insert
    nnoremap <buffer><silent> e :enew<CR>
    nnoremap <buffer><silent> i :enew <bar> startinsert<CR>
    nnoremap <buffer><silent> o :enew <bar> startinsert<CR>
endfun

" Run after "doing all the startup stuff"
autocmd VimEnter * call Start()