Magit estremamente lento in Windows. Come ottimizzo?

Sono costretto a usare Windows 10 per un progetto. Sì, preferirei usare GNU / Linux. Per mantenere la sanità mentale, ho provato a considerare Windows come un bootloader per Emacs :)

Sfortunatamente, Magit (una delle mie parti preferite di Emacs, che compensa anche la mancanza di una buona riga di comando su Windows) è insopportabilmente lento. Ho un SSD, 16 GB di RAM e un quad-core i7 ma ci vogliono otto secondi per essere eseguito magit-statussu un piccolo repository. Quindi, quando voglio mettere in scena un'altra modifica, ci vogliono circa 5 secondi per file .

Ecco cosa ho provato:

• $ git config --global core.preloadindex true
• $ git config --global core.fscache true
• $ git config --global gc.auto 256
• Aggiunta dell'intero progetto all'elenco di esclusione di Windows Defender (il mio unico AV)
• Impostando il magit-git-executablenormale msysgit che ho scaricato ( https://git-for-windows.github.io/ ). Ho controllato e git statusqui ci vuole <1 secondo. So che magit-statusfa molto di più, ma è troppo.

Qualcuno può suggerire modi per renderlo più veloce? Non riesco a immaginare nessuno che usi Magit su Windows in questo modo.

È stato suggerito che questa domanda è un duplicato, ma hanno chiesto:

Faccio fatica a capire perché Emacs ha notevolmente più brevi tempi di avvio su Ubuntu rispetto a Windows. Qualcuno conosce la risposta?

Conosco almeno alcuni motivi per cui Emacs, Git e Magit sono più lenti su Windows. Sto chiedendo come ottimizzare Magit per fare meno cose, risultati nella cache o qualcosa del genere, anche se è a scapito della funzionalità.

In realtà ho fatto molte ricerche su questo e fondamentalmente il problema è che Git per Windows fa schifo

Questo è il bug a monte: https://github.com/git-for-windows/git/issues/596 e richiede che qualcuno riscriva gli script della shell in C in modo che non ci siano più comandi di fork. Per me, è il rebase interattivo che è il vero killer (posso dare il via a un rebase interattivo, andare a fare il tè, tornare, leggere alcune notizie, bere il tè e poi forse è finito. È molto peggio di molte persone penso che lo sia), ma sono sufficienti anche chiamate di tipo generale per interrompere il passo di lavoro.

Un'alternativa potrebbe essere aggiornare jGit per supportare i comandi utilizzati da Magit e quindi eseguirlo in nailgun per ridurre il tempo di avvio di JVM, ho iniziato un thread per discutere di questo: http://dev.eclipse.org/mhonarc/lists/ jgit-dev / msg03064.html

Potresti voler leggere /programming/4485059 per alcuni potenziali accelerazioni, ma onestamente te ne accorgerai a malapena.

Qualcosa che puoi fare in magit è seguire i consigli dell'autore nell'impostare un minimal magit-statussolo per la messa in scena

;; WORKAROUND https://github.com/magit/magit/issues/2395
(define-derived-mode magit-staging-mode magit-status-mode "Magit staging"
  "Mode for showing staged and unstaged changes."
  :group 'magit-status)
(defun magit-staging-refresh-buffer ()
  (magit-insert-section (status)
    (magit-insert-untracked-files)
    (magit-insert-unstaged-changes)
    (magit-insert-staged-changes)))
(defun magit-staging ()
  (interactive)
  (magit-mode-setup #'magit-staging-mode))

quindi, conosci qualche sviluppatore C o Java esperto che sarebbe in grado di aiutarti con una delle soluzioni per correggere git o jGit?

Avendo esaminato di recente un elenco di call-processchiamate da magit-statusun altro motivo, mi è venuto in mente che alcune di esse possono essere memorizzate nella cache. Con i seguenti consigli magit-statussul repository Magit va da 1,9 a 1,3 secondi (la mia misurazione precedente di 0,8 citata nei commenti era per un computer diverso (più veloce)). Se stai già utilizzando magit-stagingl'altra risposta, probabilmente non sarà di grande aiuto: ho visto una riduzione da 0,16 a 0,12 secondi (ma questo è appena più grande del rumore di misurazione).

ATTENZIONE: Questo non si occupa di aggiornare la cache, quindi le cose potrebbero andare storte (specialmente se stai armeggiando con la tua configurazione git).

(defvar-local magit-git--git-dir-cache nil)
(defvar-local magit-git--toplevel-cache nil)
(defvar-local magit-git--cdup-cache nil)

(defun memoize-rev-parse (fun &rest args)
  (pcase (car args)
    ("--git-dir"
     (unless magit-git--git-dir-cache
       (setq magit-git--git-dir-cache (apply fun args)))
     magit-git--git-dir-cache)
    ("--show-toplevel"
     (unless magit-git--toplevel-cache
       (setq magit-git--toplevel-cache (apply fun args)))
     magit-git--toplevel-cache)
    ("--show-cdup"
     (let ((cdup (assoc default-directory magit-git--cdup-cache)))
       (unless cdup
         (setq cdup (cons default-directory (apply fun args)))
         (push cdup magit-git--cdup-cache))
       (cdr cdup)))
    (_ (apply fun args))))

(advice-add 'magit-rev-parse-safe :around #'memoize-rev-parse)

(defvar-local magit-git--config-cache (make-hash-table :test 'equal))

(defun memoize-git-config (fun &rest keys)
  (let ((val (gethash keys magit-git--config-cache :nil)))
    (when (eq val :nil)
      (setq val (puthash keys (apply fun keys) magit-git--config-cache)))
    val))

(advice-add 'magit-get :around #'memoize-git-config)
(advice-add 'magit-get-boolean :around #'memoize-git-config)