In un foglio di calcolo Google: come posso contare le righe di una determinata area che hanno un valore? Tutti i suggerimenti su questo che ho trovato fino ad ora portano a formule che contano le righe che non hanno un contenuto vuoto (compresa la formula), ma una cella con

=IF(1=2;"";"")  // Shows an empty cell

è contato pure.

Qual è la soluzione a questo semplice compito?

Crea un'altra colonna che determina se la cella di riferimento è vuota utilizzando la funzione "CountBlank". Quindi utilizzare count sui valori creati nella nuova colonna "CountBlank".

Ho appena usato =COUNTIF(Range, "<>")e contava celle non vuote per me.

=counta(range) 

• counta: "Restituisce un conteggio del numero di valori in un set di dati"

  Nota: CountAconsidera ""un valore . Solo le celle vuote (premere Elimina in una cella per cancellarla) non vengono conteggiate.

  Assistenza Google: https://support.google.com/docs/answer/3093991

• countblank: "Restituisce il numero di celle vuote in un determinato intervallo"

  Nota: CountBlankconsidera sia le celle vuote (premere cancella per svuotare una cella) sia le celle che hanno una formula che ritorna ""ad essere celle vuote .

  Assistenza Google: https://support.google.com/docs/answer/3093403

Se hai un intervallo che include formule che ne risultano "", puoi modificare la tua formula da

=counta(range)

per:

=Counta(range) - Countblank(range)

EDIT: la funzione è countblank, no countblanks, quest'ultima darà un errore.

Ecco quello che credo sia la soluzione migliore finora:

=CountIf(ArrayFormula(range<>""),TRUE)

Ecco perché in 3 semplici passaggi

Passaggio 1: Semplice come torta - Aggiungi colonna aggiuntiva

La risposta di eniacAvenger produrrà la soluzione corretta senza preoccuparsi dei casi limite come =A1<>""sembra arrivare al valore di verità / falsità corretto in base al modo in cui intuitivamente pensiamo alle celle vuote, sia vergini che vuote.

Quindi immagina di avere questi dati e vogliamo il conteggio dei non-spazi in B2:B6:

|   |      A      |   B   |    C    |
|---|-------------|-------|---------|
| 1 | Description | Value | B1<>""  |
| 2 | Text        | H     | TRUE    |
| 3 | Number      | 1     | TRUE    |
| 4 | IF -> ""    |       | FALSE   |
| 5 | IF -> Text  | h     | TRUE    |
| 6 | Blank       |       | FALSE   |

Se facessimo affidamento sulla colonna C , potremmo ottenere il conteggio dei valori in B in questo modo:

=COUNTIF(C2:C6,True)

Passaggio 2: utilizzare FormulaArrayper creare dinamicamente una colonna aggiuntiva

Però, il commento di consideRatio è valido: se hai bisogno di una colonna aggiuntiva, puoi spesso raggiungere lo stesso obiettivo con un ArrayFormulaquale può creare una colonna in memoria senza occupare spazio nel foglio.

Quindi, se vogliamo creare C in modo dinamico, possiamo usare una formula di matrice come questa:

=ArrayFormula(B2:B6<>"")

Se lo mettessimo semplicemente in C2, creerebbe l'array verticale con un solo tratto della penna:

|   |      A      |   B   |    C                     |
|---|-------------|-------|--------------------------|
| 1 | Description | Value | =ArrayFormula(B2:B6<>"") |
| 2 | Text        | H     | TRUE                     |
| 3 | Number      | 1     | TRUE                     |
| 4 | IF -> ""    |       | FALSE                    |
| 5 | IF -> Text  | h     | TRUE                     |
| 6 | Blank       |       | FALSE                    |

Passaggio 3: contare i valori nella colonna dinamica

Ma con quello risolto, non abbiamo più bisogno della colonna per visualizzare semplicemente i valori.

ArrayFormularisolverà per il seguente intervallo: {True,True,False,True,False}.
CountIfaccetta solo qualsiasi intervallo e in questo caso può contare il numero di valori True.

Quindi possiamo avvolgere CountIfi valori prodotti in ArrayFormulaquesto modo:

=CountIf(ArrayFormula(B2:B6<>""),TRUE)

Ulteriori letture

Le altre soluzioni in questo thread sono eccessivamente complesse o falliscono in casi limite particolari che ho elencato in questo foglio di prova:

Foglio di calcolo Google - CountA Test - Demo

Per quale motivo CountAfunziona nel modo strano, vedi la mia risposta qui

Per me, nessuna delle risposte ha funzionato per intervalli che includono sia celle vergini che celle vuote in base a una formula (ad es. =IF(1=2;"";""))

Ciò che ha risolto per me è questo:

=COUNTA(FILTER(range, range <> ""))

Risolto usando una soluzione che ho trovato su Google da Yogi Anand: https://productforums.google.com/d/msg/docs/3qsR2m-1Xx8/sSU6Z6NYLOcJ

L'esempio seguente conta il numero di righe non vuote nell'intervallo A3: C, ricorda di aggiornare entrambi gli intervalli nella formula con l'intervallo di interesse.

=ArrayFormula(SUM(SIGN(MMULT(LEN(A3:C), TRANSPOSE(SIGN(COLUMN(A3:C)))))))

Assicurati anche di evitare dipendenze circolari, accadrà se, ad esempio, conti il ​​numero di righe non vuote in A: C e inserisci questa formula nella colonna A o C.

Per me funziona:

=SUMPRODUCT(NOT(ISBLANK(F2:F)))

Conteggio di tutte le celle non vuote da F2 alla fine della colonna

Data la gamma A:A, Id suggerisce:

=COUNTA(A:A)-(COUNTIF(A:A,"*")-COUNTIF(A:A,"?*"))

Il problema è che COUNTA sovrasta il conteggio del numero esatto di celle con stringhe di lunghezza zero "".

La soluzione è trovare un conteggio di esattamente queste celle. Questo può essere trovato cercando tutte le celle di testo e sottraendo tutte le celle di testo con almeno un carattere

• COUNTA (A: A): celle con valore, incluse ""ma escluse le celle veramente vuote
• COUNTIF (A: A, "*"): celle riconosciute come testo, incluse ""ma escluse le celle veramente vuote
• COUNTIF (A: A, "? *"): Celle riconosciute come testo con almeno un carattere

Ciò significa che il valore COUNTIF(A:A,"*")-COUNTIF(A:A,"?*")dovrebbe essere il numero di celle di testo meno il numero di celle di testo che hanno almeno un carattere, ovvero il conteggio delle celle che contengono esattamente""

Una soluzione più semplice che funziona per me:

=COUNTIFS(A:A;"<>"&"")

Conta sia numeri, stringhe, date, ecc. Che non sono vuoti

Per quanto posso vedere, la maggior parte delle soluzioni qui contano il numero di celle non vuote e non il numero di righe con celle non vuote all'interno.

Una possibile soluzione per la gamma B3:E29è ad esempio

=SUM(ArrayFormula(IF(B3:B29&C3:C29&D3:D29&E3:E29="";0;1)))

Qui ArrayFormula(IF(B3:B29&C3:C29&D3:D29&E3:E29="";0;1))restituisce una colonna di 0(se la riga è vuota) e1 (else).

Un altro è dato nella risposta di conside Ratio .

Puoi definire una funzione personalizzata usando Apps Script (Strumenti> Script editor) chiamato ad esempio numNonEmptyRows:

function numNonEmptyRows(range) {
  Logger.log("inside");
  Logger.log(range);
  if (range && range.constructor === Array) {
    return range.map(function(a){return a.join('')}).filter(Boolean).length
  }
  else {
    return range ? 1 : 0;
  }
}

E poi usalo in una cella come questa =numNonEmptyRows(A23:C25)per contare il numero di righe non vuote nell'intervallo A23:C25;

In Fogli Google, per contare il numero di righe che contengono almeno una cella non vuota in un intervallo bidimensionale :

=ARRAYFORMULA(
  SUM(
    N(
      MMULT(
        N(A1:C5<>""),
        TRANSPOSE(COLUMN(A1:C5)^0)
      )
      >0
    )
  )
)

Dove A1: C5 è l'intervallo che stai verificando per le righe non vuote.

La formula proviene e viene spiegata nel seguente articolo da EXCELXOR - https://excelxor.com/2015/03/30/counting-rows-where-at-least-one-condition-is-met/

Un modo molto flessibile per fare questo tipo di cose è usare ARRAYFORMULA.

Ad esempio, immagina di voler contare stringhe non vuote (campi di testo), puoi usare questo codice:

=ARRAYFORMULA(SUM(IF(Len(B3:B14)>0, 1, 0)))

Quello che succede qui è che "ArrayFormula" ti consente di operare su un insieme di valori. Usando la funzione SUM si indica "ArrayFormula" per sommare qualsiasi valore dell'insieme. La clausola "If" viene utilizzata solo per controllare "vuoto" o "non vuoto", 1 per non vuoto e 0 altrimenti. "Len" restituisce la lunghezza dei diversi campi di testo, qui è dove si definisce il set (intervallo) che si desidera verificare. Infine "ArrayFormula" sommerà 1 per ogni campo all'interno del set (intervallo) in cui "len" restituisce più di 0.

Se si desidera verificare qualsiasi altra condizione, è sufficiente modificare il primo argomento della clausola IF.