Come lavorare con i puntatori a funzione in Fortran nei programmi scientifici

Ecco un uso tipico dei puntatori a funzione in C. Vorrei fare qualcosa di simile in Fortran. Ho alcune idee, ma vorrei sapere se esiste un modo canonico per farlo.

I puntatori e contesti di funzione passati dall'utente vengono memorizzati, quindi chiamati in seguito.

typedef PetscErrorCode (*TSIFunction)(TS,PetscReal,Vec,Vec,Vec,void*);
PetscErrorCode TSSetIFunction(TS ts,Vec res,TSIFunction f,void *ctx);

La funzione dell'utente viene richiamata utilizzando il loro contesto in vari momenti successivi.

In PETSc, usano anche pesantemente le tabelle dei puntatori di funzione string ->. Tutto è un plugin, quindi l'utente può registrare le proprie implementazioni e sono di prima classe.

#define PCGAMG "gamg"
  PCRegisterDynamic(PCGAMG         ,path,"PCCreate_GAMG",PCCreate_GAMG);

Ciò registra la routine di creazione in un "FList", quindi PCSetFromOptions () offre la possibilità di scegliere questo metodo rispetto a qualsiasi altra scelta. Se il sistema supporta il caricamento dinamico, è possibile saltare la dipendenza in fase di compilazione dal simbolo PCCreate_GAMG e passare semplicemente NULL, quindi il simbolo verrà cercato nella libreria condivisa in fase di esecuzione.

Si noti che questo passo oltre una "fabbrica", è un'inversione del dispositivo di controllo simile a quello che Martin Fowler chiama "localizzatore di servizio".

Nota: questo è emerso nella mia corrispondenza privata con Jed Brown, dove mi ha fatto questa domanda. Ho deciso di esternalizzarlo e vedere quali risposte le persone possono trovare.

Non è necessario utilizzare il trasferimento per emulare void *in un moderno codice Fortran. Invece, basta usare il modulo intrinseco ISO_C_BINDING , che è supportato da tutti i compilatori Fortran tradizionali. Questo modulo semplifica l'interfaccia tra Fortran e C, con alcuni avvertimenti molto minori. Si possono usare le funzioni C_LOCe C_FUNLOCper ottenere i puntatori C ai dati e alle procedure Fortran, rispettivamente.

Per quanto riguarda l'esempio PETSC sopra, presumo che il contesto sia tipicamente un puntatore a una struttura definita dall'utente, che è equivalente a un tipo di dati derivati ​​in Fortran. Questo non dovrebbe essere un problema da gestire C_LOC. L'handle TSIFunction opaco è anche molto semplice da gestire: basta usare il tipo di dati ISO_C_BINDING c_ptr, che è equivalente a void *in C. Una libreria scritta in Fortran può usare c_ptrse deve aggirare il rigoroso controllo del tipo di Fortran moderno.

C'è molto di ciò che immagino sia un linguaggio specifico di PETSc nella tua domanda (con il quale non ho familiarità), quindi potrebbe esserci una ruga qui che non capisco bene, ma forse questo sarà ancora utile per farti iniziato.

Fondamentalmente, è necessario definire l'interfaccia per la procedura, quindi è possibile passare un puntatore a una funzione che segue questa interfaccia. Il codice seguente mostra un esempio. Innanzitutto, esiste un modulo che definisce l'interfaccia e mostra un rapido esempio di un pezzo di codice che eseguirà la routine fornita dall'utente che segue tale interfaccia. Il prossimo è un programma che mostra come l'utente userebbe questo modulo e definirà la funzione da eseguire.

MODULE xmod

  ABSTRACT INTERFACE
  FUNCTION function_template(n,x) RESULT(y)
      INTEGER, INTENT(in) :: n
      REAL, INTENT(in) :: x(n)
      REAL :: y
  END FUNCTION function_template
  END INTERFACE

CONTAINS

  SUBROUTINE execute_function(n,x,func,y)
    INTEGER, INTENT(in) :: n
    REAL, INTENT(in) :: x(n)
    PROCEDURE(function_template), POINTER :: func
    REAL, INTENT(out) :: y
    y = func(n,x)
  END SUBROUTINE execute_function

END MODULE xmod


PROGRAM xprog

  USE xmod

  REAL :: x(4), y
  PROCEDURE(function_template), POINTER :: func

  x = [1.0, 2.0, 3.0, 4.0]
  func => summation

  CALL execute_function(4,x,func,y)

  PRINT*, y  ! should give 10.0

CONTAINS

  FUNCTION summation(n,x) RESULT(y)
    INTEGER, INTENT(in) :: n
    REAL, INTENT(in) :: x(n)
    REAL :: y
    y = SUM(x)
  END FUNCTION summation

END PROGRAM xprog